注册 登录  
 加关注
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

htbbzzg的博客

与朋友们分享 CAE 资料和经验

 
 
 

日志

 
 

Simwe 网站公开课的资料 - ANSYS 动力学公开课 (二) (5)  

2013-01-11 08:29:54|  分类: Simwe 网站公开课 |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

例题 3:  有预应力的模态分析 - 有孔的圆盘

    预应力模态分析概述: 
    什么是预应力模态分析和为什么要进行预应力模态分析? 
      *  预应力结构的模态分析。 
      *  一些结构在不同应力状态下表现出不同的动力学行为: 
        –  例如,吉他弦或鼓面,当拉力增加时,振动频率也会提高。 
        –  当涡轮叶片旋转时,由于离心力造成的预应力,它的固有频率会提高。 
      *  为适当的设计这些结构,无应力和预应力状态的模态分析都是需要的。
    三个主要步骤: 
      *  建模; 
      *  通过静力分析对模型施加预应力; 
      *  进行有预应力的模态分析。 
 
    本例中,将对如下圆盘施加预应力,然后确定它的自然频率。如果时间允许,确定该圆盘在无预应力时的频率和模态形状,并比较两种结果。

 
    说明: 
      *  对如图所示铝圆盘,计算前 10 个自然频率和模态。在圆盘中心孔边缘处约束径向和平面外的位移。由于沿圆周的径向均布压力 -20 lbs/inch,在圆盘中存在预应力。圆盘的材料属性如下: 
        –  弹性模量  E = 10 x 106 psi 
        –  密度 ρ= 2.3 x 10-4 lbf-sec^2/in4 
        –  泊松比  μ= 0.27 
                              Simwe 网站公开课的资料 - ANSYS 动力学公开课 (二) (5) - htbbzzg - htbbzzg的博客

  
    操作指南:
      1.   清除数据库,读入文件  disc.inp 以创建模型几何和网格。

        或者将 disc.inp 的内容拷贝到 GUI 的命令输入窗口,然后回车,执行这些命令流。 
                             Simwe 网站公开课的资料 - ANSYS 动力学公开课 (二) (5) - htbbzzg - htbbzzg的博客

    DISK.inp 文件的内容如下: 

finish
/clear
/udoc,1,date,off

expnd=1
cycsym=0
manual=0
complete=0            !  如果将此句改为 complete = 1,将会执行完整的分析,否则只是生成模型
full360=1
prestress=1

! Disc model for Dynamics seminar
!  Start with a sector
!
/filnam,disc
/uis,msgpop,3
*if,complete,eq,1,then
  !/show,disc,grph
*endif
/prep7
/title,PERFORATED DISC

! Element type, real constants, and materials
et,1,63
r,1,.1
mp,ex,1,1e7
mp,dens,1,2.3e-4
mp,prxy,1,0.27

! Solid model of sector
inrad=1
outrad=4
ang=36             ! Sector angle
outhole=0.3
inhole=0.2
outloc=3.0
inloc=2.0
dloc=outloc-inloc
!
pcirc,inrad,outrad,0,ang    ! Base disc
wpoff,outloc
pcirc,outhole      ! Circle for 1st outer hole
cswp,11,1          ! CS 11 for center of 1st outer hole
wpoff,-outloc
wprot,ang/2
wpoff,inloc
pcirc,inhole       ! Circle for inner hole
cswp,12,1          ! CS 12 for center of inner hole
wpoff,-inloc
wprot,ang/2
wpoff,outloc
pcirc,outhole      ! Circle for 2nd outer hole
cswp,13,1          ! CS 13 for center of 2nd outer hole
asba,1,all         ! Subtract circles from base
wpcsys,,0          ! Working plane back to default
wpstyle,,,, ,,,,0  ! Turn off WP display
save

! Define components for ease of meshing
csys,1
lsel,s,loc,y,0
cm,ln0_st,line        ! Straight lines at theta=0
lsel,s,loc,y,ang
cm,ln%ang%_st,line    ! Straight lines at theta=ang
csys,11
lsel,s,loc,x,outhole
cm,ln0_hole,line      ! Hole lines at theta=0
csys,13
lsel,s,loc,x,outhole
cm,ln%ang%_hole,line  ! Hole lines at theta=ang
lsel,all

! Mesh the area
lesize,ln0_st,1/6
lesize,ln%ang%_st,1/6
csys,1
lsel,u,loc,x,inrad+0.1,outrad-0.1
lesize,all,1/6
amesh,all

/view,,1,-1,1
/ang,,-60
aplot
eplot
save                 ! Important... disc.db is needed later!

!-------------------------------------------
! MODAL ANALYSIS OF SECTOR - CYCLIC SYMMETRY
!-------------------------------------------
*if,cycsym,eq,1,then
  finish
  /filnam,disc%ang%
  /prep7

  *if,manual,eq,1,then
    !Identify symmetry edges
    cmsel,s,ln0_st
    nsll,,1
    cm,disc_m01l,line         ! Lines at zero angle
    !cm,disc_m01l,node        ! Nodes at zero angle
    cmsel,s,ln%ang%_st
    nsll,,1
    cm,disc_m01h,line         ! Lines at angle=ang
    !cm,disc_m01h,node        ! Nodes at angle=ang
    cmsel,a,disc_m01l
    !/psymb,dot,1
    !nplot
    lplot
    /wait,1
  *endif         ! if manual=1

  allsel
  save


  ! Generate copy of basic sector
  !cycgen
  *if,manual,eq,1,then
    cyclic,360/ang,ang,1,disc,1 ! manual mode
  *else
    cyclic   ! automatic mode
  *endif


  ! Apply BC's on both sectors
  !   Radial and UZ constraints at inner radius
  csys,1
  lsel,,loc,x,inrad
  dl,all,,symm
  dl,all,,uz
  lsel,all
  /pbc,all,,1
  lplot
  dtran
  eplot

  ! Specify analysis type and options
  /solu
  antype,modal
  modopt,lanb,5,,,,,,2
  mxpand,5
  cycopt,hindex,0,4,1
  cycopt,stat

  ! Solve using CYCSOL
  *get,timest,active,,time,cpu
  !cycsol,0,4,360/ang,'nd0'        ! Solve
  solve
  *get,timeend,active,,time,cpu
  solvtime=timeend-timest         ! Time for solution
  finish

  ! Review results over 360 degrees
  /post1
  set,list

  *if,expnd,eq,1,then
    !expand,360/ang

    ! Plot mode shapes
    set,1,2         ! 2nd axisymmetric mode
    /cycexpand,,on
    /reset
    /plopts,info,off
    /edge,,1
    /view,,1
    /dsca,,.01
    /dist,,4.1
    pldisp,2
    /wait,1

    set,2,1
    /ang,,ang/2,zm,1
    /replot
    /wait,1
    /ang,,-ang/2,zm,1

    set,3,1
    /ang,,-ang*(3/4),zm,1
    /replot
    /wait,1
    /ang,,ang*(3/4),zm,1

    set,4,1
    /ang,,-ang*(9/8),zm,1
    /replot
    /wait,1
    /ang,,ang*(9/8),zm,1

    set,5,1
    /ang,,-ang/8,zm,1
    /replot
    /wait,1

    ! Plot UZ contours to show zero diametric lines
    /reset
    /plopts,minm,off
    /plopts,info,off
    /cval,,-1,1,100
    plnsol,u,z
    /wait,1

    set,4,1
    /replot
    /wait,1

    set,3,1
    /replot
    /wait,1

    set,2,1
    /replot
    /wait,1

    set,1,2
    /replot
    /wait,1

    !twave,ang,.1

    /cval
  *endif        ! if expnd=1

  finish
*endif          ! if cycsym=1

!-------------------------------------------
! MODAL ANALYSIS OF FULL 360-DEGREE DISC
!-------------------------------------------
! Generate full 360 degree model
*if,full360,eq,1,then
  finish
  resume,disc,db
  /filname,disc360
  /prep7
  csys,1
  agen,360/ang,all,,,0,ang,0
  nummrg,node
  nummrg,kp
  /dist,,3.5
  /edge,,1
  eplot
  /edge
  eplot
  /uis,msgpop,2

  *if,complete,eq,1,then
    ! Constraints
    lsel,,loc,x,inrad
    dl,all,,symm
    dl,all,,uz
    lsel,all
    !*do,i, ang/2, 360-(ang/2), ang
    !  csys,1
    !  wpave,(outloc-dloc),i        ! WP at (r,theta,z)
    !  cswp,11,1
    !  nsel,,loc,x,(inhole-.01),(inhole+.01)
    !  dsym,symm,x,11
    !  dofsel,s,rot
    !  ddele,all,all
    !  dofsel,all
    !*enddo
    !nsel,all
    /pbc,all,,1
    /psf,pres,,2
    lplot
    dtran
    eplot

    ! Solution
    /solu
    antype,modal
    modopt,lanb,25
    mxpand,25
    *get,timest,active,,time,cpu
    solve
    *get,timeend,active,,time,cpu
    solvtim2=timeend-timest
    finish

    ! Review results
    /post1
    set,list
    /edge,,1
    *do,i,1,5
      set,1,i
      pldisp,2
    *enddo
    finish

    !---------------------------------------------------
    ! PRESTRESSED MODAL ANALYSIS OF FULL 360-DEGREE DISC
    !---------------------------------------------------
    *if,prestress,eq,1,then
      ! Static analysis
      /solu
      antype,static
      pstres,on

      ! Pressure on outer circumference
      csys,1
      lsel,,loc,x,outrad
      sfl,all,pres,-20
      lsel,all
      lplot
      sftran
      /edge
      eplot

      solve
      finish

      /post1
      /dist,,4.5
      plnsol,s,1
      finish

      ! Prestressed modal analysis
      /solu
      antype,modal
      modopt,lanb,10
      mxpand,10
      pstres,on

      solve
      finish

      /post1
      set,list
      /edge,,1
      *do,i,1,5
        set,1,i
        pldisp,2
      *enddo
      finish
    *endif        ! if prestress=1
  *endif        ! if complete=1
*endif        ! if full360=1
!

  评论这张
 
阅读(1019)| 评论(0)
推荐 转载

历史上的今天

在LOFTER的更多文章

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2016