注册 登录  
 加关注
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

htbbzzg的博客

与朋友们分享 CAE 资料和经验

 
 
 

日志

 
 

ANSYS 入门教程 (44) - 结构线性静力分析 (b)  

2010-09-04 06:13:43|  分类: ANSYS 入门基础 |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

6.3  梁结构

    ★  梁是工程结构最为常用的结构形式之一。
    ★  ANSYS 中的梁单元有多个种类,分别具有不同的特性,是一类轴向拉压、弯曲、扭转 (3D) 单元。
    ★  梁单元在应用中应考虑许多问题,如自由度释放(铰接)、剪切变形的影响、梁截面特性、截面方向、应力计算、内力处理等。
    ★  在实际结构简化时,尚应考虑梁单元的适用条件、结点偏心与刚臂、边界条件确定等问题。

一、  几种梁单元用法与结果

    如图所示的空间结构, 分别采用BEAM4、BEAM24、BEAM44、BEAM188、BEAM189 单元进行分析,所有单元均采用缺省设置,计算结果如表所示。 

                ANSYS 入门教程 (44) - 结构线性静力分析 (b) - htbbzzg - htbbzzg的博客

 

                ANSYS 入门教程 (44) - 结构线性静力分析 (b) - htbbzzg - htbbzzg的博客

    在计算过程中,需要注意以下几个问题:
        ① 单元坐标系:单元坐标系的 X 轴总是从 I 节点指向 J 节点,BEAM4 单元当采用缺省定义时(不输入 K 节点或 Θ 角),单元坐标系的 Y 轴与总体坐标系的 Y 轴平行;如果单元坐标系的 X 轴平行于总体坐标系的 Y 轴,则单元坐标系的 Z 轴与总体坐标系的 Z 轴平行;用右手法则可确定单元坐标系的另外一轴方向。
        BEAM24 必须定义方位点。BEAM44、BEAM188、BEAM189 可采用缺省(不定义方位点),但不一定是期望的截面方向,因此建议定义方位点。这 5 种梁单元由定位点和始末节点构成的平面包含单元的 X 轴和 Z 轴。
        ② 实常数:BEAM4 单元输入实常数时,必须明确单元坐标系的方向,否则容易将惯性矩输错,即 IZZ 和 IYY 交换;对 BEAM4 的扭转惯矩 IXX 不宜缺省(缺省时为 IYY 和 IZZ之和,即极惯性矩),因为扭转惯矩一般小于极惯性矩,如此缺省对结构的扭转刚度影响很大。
        BEAM44 当为等截面梁时可采用梁截面输入,而当为变截面梁时,则只能用实常数输入。而 BEAM188 和 BEAM189 单元则可用于等截面或变截面梁。
        当采用梁截面时,实常数不必定义。
        ③ 剪切模量:剪切模量可根据实际材料确定。当 GXY、PRXY 和 NUXY 都不定义时,ANSYS 会发出警告且采用GXY=EX/2.6;如仅定义了主泊松系数 PRXY,则 ANSYS 按 GXY=0.5×EX/(1+PRXY) 计算。

     示例命令流:

        !  EX6.3  几种梁单元用法与结果


        !  EX6.3A-BEAM4 单元
        finish  $ /clear  $ /prep7
        !  ①  定义单元类型、材料特性、实常数等
        et,1,beam4  $ mp,ex,1,2.1e11  $ mp,prxy,1,0.3
        r,1,1032e-5,158936e-9,1947744e-11,0.18,0.3  $  rmore,,110976e-11
        r,2,1032e-5,1947744e-11,158936e-9,0.3,0.18  $ rmore,,110976e-11
        !  ② 创建几何模型、施加约束和集中荷载、定义所有线都划分 10 个单元
        k,1  $ k,2,,4  $ k,3,3,4  $ k,4,3,4,-2  $ l,1,2  $ l,2,3  $ l,3,4
        dk,1,all  $ dk,4,ux,,,,uy,uz  $ fk,3,fy,-15000  $ fk,3,fz,8000  $ lesize,all,,,10
        !  ③  选择线、定义线属性、划分网格、施加单元线荷载
        lsel,s,,,1  $ latt,1,1,1  $ lmesh,all  $ esll,s  $ sfbeam,all,2,pres,3000
        lsel,s,,,2  $ latt,1,1,1  $ lmesh,all  $ esll,s  $ sfbeam,all,2,pres,2000
        lsel,s,,,3  $ latt,1,2,1  $ lmesh,all  $ esll,s  $ sfbeam,all,1,pres,-1000
        !  ④ 求解
        allsel  $ /solu  $ solve
        !  ⑤  后处理
        /post1  $ pldisp,1

        !  ⑤ A定义单元表
        etable,fxi,smisc,1  $ etable,fxj,smisc,7                         !单元杆端FX
        etable,fyi,smisc,2  $ etable,fyj,smisc,8                         !单元杆端FY
        etable,fzi,smisc,3  $ etable,fzj,smisc,9                         !单元杆端FZ
        etable,mxi,smisc,4  $ etable,mxj,smisc,10                    !单元杆端MX
        etable,myi,smisc,5  $ etable,myj,smisc,11                   !单元杆端MY
        etable,mzi,smisc,6  $ etable,mzj,smisc,12                    !单元杆端Mz
        etable,smini,nmisc,2  $ etable,sminj,nmisc,4               !单元最小应力
        !  特别地,BEAM4 单元的应力计算基于输入的截面高度 TKZ 和 TKY,按中性轴在其 1/2 处
        !  计算应力,因此该应力对于双轴对称截面可用,其它截面形式要慎用,以免出错。
        !  ⑤ B 显示单元坐标系中的结果
        plls,fxi,fxj  $ plls,fyi,fyj  $ plls,fzi,fzj  $ plls,mxi,mxj  $ plls,myi,myj
        plls,mzi,mzj  $ plls,smini,sminj  $ prnsol,u  $ prrsol

 

        !  EX6.3B-BEAM24 单元
        finish  $ /clear  $ /prep7
        !  ①  定义单元类型、材料特性、实常数等
        et,1,beam24,1  $ mp,ex,1,2.1e11  $ mp,prxy,1,0.3
        r,1,-0.09,-0.14,0,0.09,-0.14,0.02
        rmore,0,-0.14,0,0,0.14,0.012  $ rmore,-0.09,0.14,0,0.09,0.14,0.02
        !  ② 创建几何模型、施加约束和集中荷载、定义所有线都划分 10 个单元
        k,1$k,2,,4  $ k,3,3,4  $ k,4,3,4,-2  $ k,51,-3,2  $ k,52,2,6
        k,53,0,4,-1  $ l,1,2  $ l,2,3  $ l,3,4
        dk,1,all  $ dk,4,ux,,,,uy,uz  $ fk,3,fy,-15000  $ fk,3,fz,8000  $ lesize,all,,,10
        !  ③  选择线、定义线属性、划分网格、施加单元线荷载
        lsel,s,,,1  $ latt,1,1,1,,,51  $ lmesh,all  $ esll,s  $ sfbeam,all,1,pres,3000
        lsel,s,,,2  $ latt,1,1,1,,,52  $ lmesh,all  $ esll,s  $ sfbeam,all,1,pres,2000
        lsel,s,,,3  $ latt,1,1,1,,,53  $ lmesh,all  $ esll,s  $ sfbeam,all,1,pres,1000  $ allsel
        !  ④ 求解
        /solu  $ solve

 

        !  EX6.3C-BEAM44 单元
        finish  $ /clear  $ /prep7
        !  ① 定义单元类型、材料特性、梁截面等
        et,1,beam44  $ mp,ex,1,2.1e11  $ mp,prxy,1,0.3
        sectype,1,beam,i   $ secoffset,cent  $ secdata,0.18,0.18,0.3,0.02,0.02,0.012
        !  ② 创建几何模型、施加约束和集中荷载、定义所有线都划分 10 个单元
        k,1  $ k,2,,4  $ k,3,3,4  $ k,4,3,4,-2  $ k,51,-3,2  $ k,52,2,6
        k,53,0,4,-1  $ l,1,2$l,2,3  $ l,3,4
        dk,1,all  $ dk,4,ux,,,,uy,uz  $ fk,3,fy,-15000  $ fk,3,fz,8000  $ lesize,all,,,10
        !  ③选择线、定义线属性、划分网格、施加单元线荷载
        lsel,s,,,1  $ latt,1,,1,,,51,1  $ lmesh,all  $ sfbeam,all,1,pres,3000
        lsel,s,,,2  $ latt,1,,1,,,52,1  $ lmesh,all  $ esll$sfbeam,all,1,pres,2000
        lsel,s,,,3  $ latt,1,,1,,,53,1  $ lmesh,all  $ esll$sfbeam,all,1,pres,1000  $ allsel
        /solu  $ solve

 

        !  EX6.3D-BEAM188/189 单元(仅改变 188 或 189 即可)
        finish  $ /clear  $ /prep7
        !  ① 定义单元类型、材料特性、梁截面等
        et,1,beam189  $ mp,ex,1,2.1e11  $ mp,prxy,1,0.3
        sectype,1,beam,i  $ secoffset,cent  $ secdata,0.18,0.18,0.3,0.02,0.02,0.012
        k,1  $ k,2,,4  $ k,3,3,4  $ k,4,3,4,-2  $ k,51,-3,2  $ k,52,2,6
        k,53,0,4,-1  $ l,1,2  $ l,2,3  $ l,3,4
        dk,1,all  $ dk,4,ux,,,,uy,uz  $ fk,3,fy,-15000  $ fk,3,fz,8000  $ lesize,all,,,10
        !  ③ 选择线、定义线属性、划分网格、施加单元线荷载
        lsel,s,,,1  $ latt,1,,1,,,51,1  $ lmesh,all  $ sfbeam,all,1,pres,3000
        lsel,s,,,2  $ latt,1,,1,,,52,1  $ lmesh,all  $ esll$sfbeam,all,1,pres,2000
        lsel,s,,,3  $ latt,1,,1,,,53,1  $ lmesh,all  $ esll$sfbeam,all,1,pres,1000$allsel
        /solu  $ solve

 

二、  梁单元自由度释放与耦合自由度

     节点自由度释放(与自由度凝聚相同)就是将该节点的某个自由度“放松”,即铰接于该节点单元的单元杆端弯矩为零。ANSYS 中具有自由度释放功能的有 BEAM44、BEAM188/189 三个单元, 且它们的释放方式不同。BEAM188/189 单元采用 ENDRELEASE 命令释放自由度,相当于耦合自由度,其操作可在全刚接有限元模型的基础上进行;而 BEAM44 采用 KEYOPT(7) 释放自由度,其方法是释放“刚度矩阵”,其操作是在建立单元的过程中完成的。
     耦合自由度就是强迫两个或多个自由度“相等”,耦合自由度集包含一个主自由度和一个或多个从自由度,只有主自由度保存在矩阵方程中,而其它从自由度则从方程中删除,故耦合自由度实际上是降低了平衡方程的个数。对梁结构而言,在创建模型或单元时铰接于一点的各杆件的端点(关键点或节点)各自独立,如 3 个杆件铰接在一起,则在同一几何位置创建 3 个关键点或节点,进而耦合其自由度。

    在大变形时,BEAM44 单元的节点自由度释放会“随动”,而耦合自由度则不会。
    1.   耦合自由度命令

                ANSYS 入门教程 (44) - 结构线性静力分析 (b) - htbbzzg - htbbzzg的博客

     ⑴   定义、修改耦合自由度集
     命令: CP,NSET,Lab,NODE1,NODE2,NODE3,NODE4,NODE5,NODE6,NODE7,NODE8,NODE9,NODE10,NODE11,NODE12,NODE13, NODE14,NODE15,NODE16,NODE17
          NSET - 耦合自由度集编号,其值可取:
               =N:任意号;
               =HIGH:最高既有集号,为 Lab≠ALL 时的缺省设置。
               =NEXT:最高既有集号 +1,为 Lab=ALL 时的缺省设置。
          Lab - 拟耦合的自由度标识符,对结构分析可用的有:UX、UY、UZ、ROTX、ROTY、ROTZ 或 ALL(位于节点坐标系)。
          NODE1~NODE17 - 节点号。节点号不能重复,负节点号表示从耦合集中删除该节点;第1个节点为主节点,也可为 ALL - 节点选择集中的所有节点号。
               ★  同一自由度只能出现在一个耦合集中,否则会出现错误。
               ★  有约束的自由度不能包含在耦合集中。
               ★  在减缩自由度分析中,如果主自由度(MDOF)包含在耦合集中,则必须是耦合集中的主自由度(相对从自由度而言)。
               ★  对显式动力分析,仅仅 UX、UY、UZ 自由度可耦合,转动自由度不能耦合。
               ★  耦合集中的节点不必是重合的,也不必是位于同一线上,它们可以是任意的。

     ⑵ 耦合重合节点
     命令:CPINTF, Lab, TOLER
          Lab - 拟耦合的自由度标识符,同 CP 命令中的参数。
          TOLER - 判定节点是否重合的误差,缺省为 0.0001。TOLER 的计算基于总体直角坐标系中节点坐标的最大差值,只有在误差范围内的节点才被认为是重合的。


2.   梁结构耦合自由度示例
     如图所示平面结构,首先创建几何模型,然后由几何模型生成有限元模型。在铰接点位置创建了重合的关键点编号,在生成有限元模型时便创建了重合的节点,即铰接于一点的各单元具有独立的节点。
     耦合自由度是对有限元模型的节点操作,因此关键点不能直接进行自由度的耦合操作。

                ANSYS 入门教程 (44) - 结构线性静力分析 (b) - htbbzzg - htbbzzg的博客

 

        !  EX6.4  耦合自由度
        finish  $ /clear  $ /prep7
        !  ①  定义单元类型、材料性质、实常数、几何模型、施加约束
        et,1,beam3  $ mp,ex,1,2.1e11  $ mp,prxy,1,0.3  $ r,1,0.007848,4.9087e-6,0.1
        k,1$k,2,0,4  $ k,3,0,4  $ k,4,3,4  $ k,5,3,4  $ k,6,3,0  $ k,7,3,7  $ k,8,6,7
        k,9,6,7  $ k,10,6,7  $ k,11,6,4  $ k,12,9,7  $ l,1,2  $ l,3,4  $ l,6,5  $ l,5,7  $ l,7,8  $ l,11,10
        l,9,12  $ dk,1,all  $ dk,6,all  $ dk,11,all  $ dk,12,ux,,,,uy

        !  ②  生成有限元模型,施加单元荷载
        lesize,all,,,8  $ lmesh,all  $ lsel,s,,,2  $ esll  $ sfbeam,all,1,pres,2000
        lsel,s,,,5,7,2  $ esll  $ sfbeam,all,1,pres,3000  $ allsel
        !  ③ A  关键点 2 和 3 位置的节点创建约束方程,UY 和 ROTZ 相等
        ksel,s,,,2,3  $ nslk,s  $ cp,next,rotz,all  $ cp,next,uy,all
        !  ③ B  关键点 4 和 5 位置的节点创建约束方程,UX 和 UY 相等
        ksel,s,,,4,5  $ nslk,s  $ cp,next,ux,all  $ cp,next,uy,all
        !  ③ C  关键点 8、9 和 10 位置的节点创建约束方程,UX 和 UY 相等
        ksel,s,,,8,10  $ nslk,s  $ cp,next,ux,all  $ cp,next,uy,all  $ allsel  $ finish
        !  ④ 求解及后处理
        /solu  $ solve  $ finish$/post1  $ pldisp,1
        etable,mi,smisc,6  $ etable,mj,smisc,12  $ plls,mi,mj,-1

                ANSYS 入门教程 (44) - 结构线性静力分析 (b) - htbbzzg - htbbzzg的博客

 

                ANSYS 入门教程 (44) - 结构线性静力分析 (b) - htbbzzg - htbbzzg的博客

 

3.   BEAM18X 系列单元的端点自由度释放
    采用上图结构以 BEAM189 为例,说明端点释放的操作过程。
        ★ 采用自由度释放时,按刚接点创建几何模型,不需要在同一位置创建多个关键点。
        ★ 多杆铰接时应同时释放自由度,否则在不同的耦合自由度集中会出现同一自由度。
        ★ 自由度释放与直接创建耦合自由度互补,即释放某个自由度,则在耦合自由度集中无该自由度。BEAM18X 系列所释放的自由度基于节点坐标系。
    在 ENDRELEASE 命令中, 相邻单元的夹角限值为 TOLERANCE(缺省为 20°)。一种特殊的情况是仅仅两个相邻单元在一条线上(夹角限值失效), 此时需使用 TOLERANCE=-1 参数并选择这两个单元,然后实施自由度释放。

    示例:

        !  EX6.5 BEAM189 自由度释放
        finish  $ /clear  $ /prep7
        et,1,beam189  $ mp,ex,1,2.1e11  $ mp,prxy,1,0.3                                                  ! 定义单元类型、材料性质
        sectype,1,beam,csolid  $ secdata,0.05                                                                   ! 定义梁截面数据
        k,1  $ k,2,0,4  $ k,3,3  $ k,4,3,4  $ k,5,3,7  $ k,6,6,4  $ k,7,6,7  $ k,8,9,7                ! 创建关键点
        k,100,-10,110                                                                                                          ! 创建定位点
        l,1,2  $ l,3,4  $ l,4,5  $ l,2,4  $ l,6,7  $ l,5,7  $ l,7,8                                                   ! 创建线
        dk,1,all  $ dk,3,all  $ dk,6,all  $ dk,8,ux,,,,uy                                                             ! 施加约束(因固结未约束 UZ)
        latt,1,,1,,100,,1  $ lesize,all,,,9  $ lmesh,all                                                               ! 对线赋属性、划分单元
        lsel,s,loc,y,4  $ esll  $ sfbeam,all,1,pres,2000                                                          ! 施加单元荷载
        lsel,s,loc,y,7  $ esll  $ sfbeam,all,1,pres,3000                                                          ! 施加单元荷载
        lsel,s,,,1,4,3  $ esll  $ endrelease,,,ux                                                                      ! 最左边位置,释放自由度 UX
        lsel,s,,,2,4,2  $ esll  $ endrelease,,,rotz                                                                    ! 中间位置,释放自由度 ROTZ
        lsel,s,,,5,7  $ esll  $ endrelease,,,rotz  $ allsel                                                          ! 最右边位置,释放自由度 ROTZ
        cplist  $ finish  $ /solu  $ solve  $ finish                                                                     !求解与后处理
        /post1  $ pldisp,1  $ etable,mi,smisc,2  $ etable,mj,smisc,15  $ plls,mi,mj

 

4.   BEAM44 单元自由度释放
    BEAM44 单元的自由度释放采用 KEYOPT(7) 设置,有多少不同的自由度释放就需要定义多少种单元,因此其自由度释放要比前两种方法繁琐。当采用定位点定义 BEAM44 单元截面方位时,由 IJK 构成的平面包含单元的 X 轴和 Z 轴,与缺省时的单元坐标系不同。

    示例:
        !  EX6.6 BEAM44 自由度释放
        finish  $ /clear  $ /prep7
        et,1,beam44  $ et,2,beam44  $ et,3,beam44                 ! 定义单元类型 3 种
        keyopt,2,7,100000                                                         ! 释放第 2 种单元的 I 节点的 UX
        keyopt,3,8,10                                                                 ! 释放第 3 种单元的 J 节点的 ROTY
        mp,ex,1,2.1e11  $ mp,prxy,1,0.3                                    ! 定义材料性质
        sectype,1,beam,csolid  $ secdata,0.05                          ! 定义梁截面数据

        k,1  $ k,2,0,4  $ k,3,3,0  $ k,4,3,4  $ k,5,3,7  $ k,6,6,4  $ k,7,6,7  $ k,8,9,7        ! 创建关键点
        k,100,-10,110  $ l,1,2  $ l,3,4  $ l,4,5  $ l,2,4  $ l,6,7  $ l,5,7  $ l,7,8                   ! 创建定位点和线
        dk,1,all  $ dk,3,all  $ dk,6,all  $ dk,8,ux,,,,uy                                                       !施加约束
        latt,1,,1,,100,,1  $ lesize,all,,,9  $ lmesh,all                                                         !划分单元
        lsel,s,loc,y,4  $ esll  $ sfbeam,all,1,pres,2000                                                    !施加单元荷载
        lsel,s,loc,y,7  $ esll  $ sfbeam,all,1,pres,3000  $ allsel
        emodif,28,type,2                                                                         ! 将 28 单元修改为单元类型 2, 即该单元的I节点释放 UX
        emodif,36,type,3                                                                         ! 将 36,54,45 单元修改为单元类型 3, 即释放这些单元的 J 节点
        emodif,54,type,3                                                                         ! 的 ROTY。最右边位置上的 3 个杆件,释放两个即可。
        emodif,45,type,3
        finish  $ /solu  $ solve  $ finish  $ /post1
        pldisp,1  $ etable,mi,smisc,5  $ etable,mj,smisc,11  $ plls,mi,mj

 

三、  曲梁及线荷载的施加

    曲梁结构可采用直线梁单元近似模拟,如采用适当数量的单元也可获得较为满意的结果。可采用 3 节点 BEAM189 单元更加准确的模拟曲梁,因 3 节点 BEAM189 可适应曲线边界。
1. 斜梁
    ★  在梁结构上施加分布荷载,只能施加到单元上。
    ★  只可施加垂直单元轴线或平行单元轴线的分布荷载。
    ★  斜向分布荷载可用:
        ◆  等效到节点上的集中荷载
        ◆  分解后分别施加
        ◆  用惯性荷载施加(模拟自重)
        ◆  表面效应单元等方法。

    如图所示斜梁及所受均布线荷载,可首先将分布荷载 QH 转化到沿斜梁轴线分布的荷载 QS(图 6B),然后再将 QS 分解为 QSV(图 C)和 QSP(图 D),此时可用 SFBEAM 命令施加,具体过程如命令流中的详细说明。

                    ANSYS 入门教程 (44) - 结构线性静力分析 (b) - htbbzzg - htbbzzg的博客                 
                        ANSYS 入门教程 (44) - 结构线性静力分析 (b) - htbbzzg - htbbzzg的博客

     QH 为已知的均布荷载集度,θ 为杆件轴线与均布荷载基线的夹角,I 和 J 为节点号。

    一个人字结构,承受均布荷载如图:

                ANSYS 入门教程 (44) - 结构线性静力分析 (b) - htbbzzg - htbbzzg的博客
 

     其计算分析命令流如下。

          !  EX6.7  斜梁施加水平均布荷载
          finish  $ /clear  $ /prep7
          !  定义两个均布荷载参数、定义单元类型、材料性质、单元实常数、创建模型
          qh1=10000  $ qh2=15000  $ et,1,beam3  $ mp,ex,1,2.1e11  $ mp,prxy,1,0.3
          r,1,0.01424,0.1922e-3,0.3  $ k,1  $ k,2,5,3  $ k,3,10  $ l,1,2$l,2,3
          dk,1,ux,,,,uy  $ dk,3,uy  $ lesize,all,,,5  $ lmesh,all
          !  选择线 L1 及相关单元,等效并分解荷载,施加两方向荷载
          lsel,s,,,1  $ esll
          csref=(kx(2)-kx(1))/distkp(1,2)  $ siref=(ky(2)-ky(1))/distkp(1,2)
          qs=qh1*csref  $ qsv=qs*csref  $ qsp=qs*siref
          sfbeam,all,1,pres,qsv  $ sfbeam,all,2,pres,-qsp
          !  选择线 L2 及相关单元,等效并分解荷载,施加两方向荷载
          lsel,s,,,2  $ esll
          csref=(kx(3)-kx(2))/distkp(2,3)  $ siref=(ky(3)-ky(2))/distkp(2,3)
          qs=qh2*csref  $ qsv=qs*csref  $ qsp=qs*siref
          sfbeam,all,1,pres,qsv  $ sfbeam,all,2,pres,-qsp  $ allsel
          !  求解及后处理
          /solu  $ solve  $ /post1  $ prrsol
          etable,mi,smisc,6  $ etable,mj,smisc,12  $ plls,mi,mj,-1

 

2.   曲梁
    曲梁径向和切向分布荷载可在圆柱坐标系下直接施加,而非径向和切向分布荷载也可采用类似斜梁的方法,即将荷载等效到沿曲梁轴线分布,然后将荷载分解为径向和切向两部分施加。曲线较斜直线等效与分解要复杂,如图所示的结构简图,其分解后为:

                      ANSYS 入门教程 (44) - 结构线性静力分析 (b) - htbbzzg - htbbzzg的博客

                     ANSYS 入门教程 (44) - 结构线性静力分析 (b) - htbbzzg - htbbzzg的博客

    当单元划分的足够小时,导数可为单元两节点的坐标差。实际上当单元大小适当时,结果就具有足够的精度。斜梁为曲梁的特例。

  评论这张
 
阅读(4383)| 评论(6)
推荐 转载

历史上的今天

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2017