注册 登录  
 加关注
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

htbbzzg的博客

与朋友们分享 CAE 资料和经验

 
 
 

日志

 
 

ANSYS 动力分析 (4) - 模态分析实例 (1)  

2010-09-13 07:16:53|  分类: ANSYS 动力分析 |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |
       这些实例包括两个问题:
1.    平板中央开孔模型的模态分析
       一步一步地描述了如何进行模态分析;
       既可以由学员自己来练习这个问题,也可以由老师把这个问题作为范例来讲。
2.  对模型飞机机翼进行模态分析
       这个问题留给学员做练习。
       细节部分请参考动力学实例分析补充材料。
 
  为了方便大家学习,这里给出具体操作过程,供大家参考。
 
 
1.    平板中央开孔模型的模态分析 :
    说明:
    确定一个有孔方板的前 10 阶频率。假设约束板在孔边缘的径向位移。板的材料为铝,属性如下: 
    –  弹性模量 E = 10 x 106 psi 
    –  密度 ρ = 2.4 x 10-4 lbf-sec2/in4 
    –  泊松比 μ = 0.27
                   ANSYS 动力分析 (4) - 模态分析实例 (1) - htbbzzg - htbbzzg的博客
 

    操作过程:
    1.  清除数据库并读入文件  plate.inp 以创建几何模型和网格。
                  ANSYS 动力分析 (4) - 模态分析实例 (1) - htbbzzg - htbbzzg的博客
 
  
    2.  定义材料属性 
    Preprocessor > Material Props > Material Models… 
      ?  依次双击: 
        –… Structural … Linear … Elastic … Isotropic 
            ?  EX = 10e6 (弹性模量,单位 psi) 
            ?  PRXY = 0.27 (泊松比) 
            ?  OK 
        –… Structural … Density 
            ?  DENS = 2.4e-4  (密度,单位: lbf-sec2/in4) 
            ?  OK 
    退出材料对话框。

                  ANSYS 动力分析 (4) - 模态分析实例 (1) - htbbzzg - htbbzzg的博客
  

3. 进入 /Solution,选择模态分析:
    Solution > New Analysis…  选择 Modal,然后 OK。
                  ANSYS 动力分析 (4) - 模态分析实例 (1) - htbbzzg - htbbzzg的博客
 
  
 4.  设置分析选项:
      Solution > Analysis Options…
        使用 Block Lanczos 方法 (默认)
        抽取 10 个模态;扩展 10 个模态
        可计算单元结果 … 按 OK
        在下一个对话框中接受默认设置
                  ANSYS 动力分析 (4) - 模态分析实例 (1) - htbbzzg - htbbzzg的博客
 
 
5.   约束孔的径向位移:
    Utility Menu: Plot > Lines
    Solution > Loads- Apply > Displacement > Symmetry BC > On Lines > 选取孔边缘线,按下 OK。
    注意:(1)  这里在孔边缘处施加对称约束,可以起到约束径向位移的作用,请想一想,为什么?
          (2)  这里没有对 z 向位移的约束,后面会出现零频率,即存在刚体运动。
                  ANSYS 动力分析 (4) - 模态分析实例 (1) - htbbzzg - htbbzzg的博客
 
  
6.   开始求解:
    [Solution >] -> Solve -> Current LS
    在 /STAT 窗口中检查求解信息,然后按下 OK。
                  ANSYS 动力分析 (4) - 模态分析实例 (1) - htbbzzg - htbbzzg的博客
 
 
  
7.   查看结果,首先列出频率结果:
    General Postproc > Results Summary
    可以看到,存在一个零频率,说明约束不足。
                  ANSYS 动力分析 (4) - 模态分析实例 (1) - htbbzzg - htbbzzg的博客
 
  
8.  绘制第一个模态形状:
    General Postproc > Read Results > First Set
    再 Plot Results > Deformed Shape…
    选择 “Def and undef edge” 并按 OK
    可以看到,这是一个 Z 向的刚体运动模态。
                  ANSYS 动力分析 (4) - 模态分析实例 (1) - htbbzzg - htbbzzg的博客
 
9.   显示下一个模态:
    Read Results > Next Set
    Utility Menu: Plot > Replot
    这是一个面内转动模态
                  ANSYS 动力分析 (4) - 模态分析实例 (1) - htbbzzg - htbbzzg的博客
 
  
    云图显示下一个模态:在 General Postproc 中
      Read Results > Next Set
      Plot Results > Contour Plot > Nodal Solu > Disp…
                  ANSYS 动力分析 (4) - 模态分析实例 (1) - htbbzzg - htbbzzg的博客
 
 
10.   云图显示后续模态:
     Read Results > Next Set
     Plot Results > Contour Plot > Nodal Solu > Disp…
11.   动画显示模态
     Utility Menu: PlotCtrls > Animate > Mode Shape…
        10 frames
        Time delay = 0.05
        (其余用默认值)
  
    为消除刚体模态,可以增加对 Uz 和 ROTz 的约束。
    自己试试看?
 
        附录: plate.inp 文件内容
 
! 1:
! corrected the hrcplx HRCPLX command line to reflect the negative phase angle
! to run harmonic only set
! 2:
! modified transient option to match PPT slides of dynamics training M4-50 ff
!
!    Uwe, Kx Inc., 11/30/00
!
! ********************************************
finish
/clear
/udoc,1,date,off
model=1
qtr=0
complete=0            ! 如果将此句改为 complete = 1,将会执行完整的分析,否则只是生成模型
modal_x=1
harm=0
tran=0
! DYNAMICS WORKSHOP
!   Square plate with a hole
!
/filnam,plate
/title,PLATE DYNAMIC ANALYSIS
! Build the model
*if,model,eq,1,then
  /prep7
  et,1,63       ! Shell element type
  r,1,0.1       ! Shell thickness
  *if,complete,eq,1,then
    mp,ex,1,1e7        ! Material properties
    mp,prxy,1,0.27
    mp,dens,1,2.4e-4 
  *endif
  !   Start with quarter plate
  xwidth=6
  yheight=6
  holerad=0.75
  rect,,xwidth,,yheight
  pcirc,holerad
  asba,1,2
  *if,complete,eq,1,then
    !/show,plmodel,grph
    !/plopts,leg2,off
  *endif
  /view,,1,1,1
  aplot
  smrt,6
  amesh,all
  eplot
  save,plate_qtr,db
  *if,complete,eq,1,then
    ! Symmetry BC
    csys,0                  ! Select quarter symmetry lines
    lsel,,loc,x,0
    lsel,a,loc,y,0
    ! dl,all,,symm            ! Symmetry BC
    lsel,all
    dtran
    /pbc,u,,1
    eplot
    save,plate_qtr_sym,db
  *endif
  !   Generate full plate
  arsym,x,all        ! Two reflect operations
  arsym,y,all
  nummrg,node
  nummrg,kp
  aplot
  eplot
  /edge,,1
  eplot
  /edge
  finish
  save,plate_full,db
*endif             ! if model=1
!-----------------------------------------
!   STATIC ANALYSIS - FULL PLATE PRESTRESS
!-----------------------------------------
*if,complete,eq,1,then
  *if,modal_x,eq,1,then
    ! Choose analysis type and options
    /solu
    antype,static           ! Static analysis
    pstres,on               ! Prestress effects ON
    ! Apply boundary conditions and solve
    csys,1                  ! Select hole lines
    lsel,,loc,x,holerad
    dl,all,,symm            ! Radial constraints at selected lines
    lsel,all
    /show,plstatic,grph
    /pbc,all,,1
    lplot
    aplot
    dtran
    eplot
    csys,0
    lsel,,loc,y,yheight     ! Select top and bottom lines...
    lsel,a,loc,y,-yheight
    sfl,all,pres,-20        ! ... and apply traction
    lsel,all
    sftran
    /psf,pres,,2
    eplot
    pivcheck,off            ! Turn off pivot checking
    solve
    finish
    /post1
    /title,PLATE PRESTRESS
    plnsol,s,y
    finish
    !-----------------------------------
    !   MODAL ANALYSIS - FULL PLATE
    !-----------------------------------
    ! Choose analysis type and options
    /solu
    antype,modal            ! Modal analysis
    modopt,lanb,10          ! Block Lanczos, 10 modes
    mxpand,10,,,yes         ! Expand all 10 modes
    pstres,on               ! Prestress ON
    ! Apply boundary conditions and solve
    solve
    finish
    ! Review results
    /post1
    set,list
    /show,plmodalps,grph
    *do,i,1,10
      set,,i
      pldisp,2
    *enddo
    *if,animate,eq,1,then
      ! For animation, cut & paste the following in interactive mode
      /plopts,info,off         ! Legend column off
      /plopts,frame,off        ! Frame off
      /ui,wsiz,0,0,400,325     ! Graphics window location and size (undocumented)
      /dev,text,1,200
      /triad,off
      /edge,,1
      set,,1
      pldisp,2
      anmode,10,.05
    *endif        ! if animate=1
    finish

    ! Re-do modal analysis with prestress off
    /solu
    pstres,off
    /title,PLATE STRESS-FREE
    solve
    finish
    /post1
    set,list
    /show,plmodal,grph
    *do,i,1,10
      set,,i
      pldisp,2
    *enddo
    finish
    ! Re-do modal analysis with normalization to unity
    /solu
    modopt,lanb,10,,,,on
    solve
    finish
    /post1
    *do,i,3,10
      set,,i
      plnsol,s,eqv
    *enddo
    finish
    !-----------------------------------
    !   MODAL ANALYSIS - QUARTER PLATE
    !-----------------------------------
    *if,qtr,eq,1,then
      resume,plate_qtr,db     ! Resume quarter plate model
      /filnam,plate_qtr
      /show,plqtr,grph
      ! Choose analysis type and options
      /solu
      antype,modal            ! Modal analysis
      modopt,lanb,5           ! Block Lanczos, 5 modes
      mxpand,5,,,yes          ! Expand all modes
      ! Apply boundary conditions and solve
      csys,1                  ! Select hole lines
      lsel,,loc,x,holerad
      dl,all,,symm            ! Radial constraints
      !  First load step: symmetry BC
      csys,0                  ! Select quarter symmetry lines
      lsel,,loc,x,0
      lsel,a,loc,y,0
      dl,all,,symm            ! Symmetry BC
      lsel,all
      dtran
      /pbc,u,,1
      /title,QUARTER PLATE WITH SYMMETRY BC
      eplot
      solve
      !  Second load step: anti-symmetry BC
      csys,0                  ! Select quarter symmetry lines
      lsel,,loc,x,0
      lsel,a,loc,y,0
      dldele,all,all
      dl,all,,asymm           ! Anti-symmetry BC
      lsel,all
      dtran
      /title,QUARTER PLATE WITH ANTI-SYMMETRY BC
      eplot
      solve
      ! Review results
      /post1
      set,list
      *do,i,1,5
        set,1,i
        pldisp,2
        set,2,i
        pldisp,2
      *enddo
      !anmode,10,.05
      finish
    *endif         ! if qtr=1
  *endif         ! if modal_x=1
  !-----------------------------------
  !   HARMONIC ANALYSIS
  !-----------------------------------
  *if,harm,eq,1,then
    finish
    *if,qtr,eq,1,then
      resume,plate_qtr_sym,db   ! Quarter plate
    *else
      resume,plate_full,db      ! Whole plate
    *endif
    /filnam,plharm
    /show,plharm,grph
    /solu
    antype,harmic         ! Harmonic analysis
    hropt,full
    dmprat,0.2            ! Damping ratio
    !
    csys,1
    nsel,s,loc,x,.74,.76
    cm,n_hole,node
    dofsel,u,rot          ! Unselect ROT dof
    dsym,symm,x,1         ! Radial constraint around hole
    dofsel,all
    ksel,s,loc,x,6.1,9
    nslk
    cm,n_corner,node
    d,all,uz              ! UZ constraint at corner node(s)
    allsel
    /title,PLATE HARMONIC ANALYSIS- CONSTRAINTS
    /pbc,u,,1
    eplot
    f,n_hole,fz,10        ! 10-lb FZ forces around hole
    /title,PLATE HARMONIC ANALYSIS- CONSTRAINTS & FORCES
    /pbc,f,,1
    eplot
    harfrq,0,40           ! Frequency range
    nsubst,4
    kbc,1
    solve
    harfrq,40,60
    nsubst,10
    solve
    !
    /post26
    csys,0
    nsol,2,node(0.75,0,0),u,z
    /title,PLATE HARMONIC ANALYSIS- DISP VS FREQ
    /plopts,info,on
    /plopts,leg2,off
    plvar,2
    prcplx,1
    prvar,2
    finish
    !
    /post1
    set,list
    /title,PLATE HARMONIC ANALYSIS
    hrcplx,2,4,-85.7
    /dsca,,1
    pldisp,2
    plnsol,s,eqv
    finish
  *endif    ! if harm=1
  ! End of harmonic analysis
  !-----------------------------------
  !   TRANSIENT ANALYSIS
  !-----------------------------------
  *if,tran,eq,1,then
    finish
    *if,qtr,eq,1,then
      resume,plate_qtr_sym,db   ! Quarter plate
    *else
      resume,plate_full,db      ! Whole plate
    *endif
    /filnam,pltran
    /show,pltran,grph
    /solu
    antype,trans          ! Transient analysis
    trnopt,full
    d_beta=0.0005
    betad,d_beta
    !alphad,3
    !
    csys,1
    nsel,s,loc,x,.74,.76
    cm,n_hole,node
    dofsel,u,rot          ! Unselect ROT dof
    dsym,symm,x,1         ! Radial constraint around hole
    dofsel,all
    ksel,s,loc,x,6.1,9
    nslk
    cm,n_corner,node
    d,all,uz              ! UZ constraint at corner node(s)
    allsel
    /title,PLATE TRANSIENT ANALYSIS- CONSTRAINTS
    /pbc,u,,1
    eplot
    !
    ! Define a force table array
    *dim,force,table,4,1,,time
    force(1,0,1) = 0      ! Time values
    force(2,0,1) = 0.08
    force(3,0,1) = 0.085
    force(4,0,1) = 1
    force(0,1,1) = 0      ! Force values
    force(1,1,1) = -20
    force(2,1,1) = -20
    force(3,1,1) = 0
    force(4,1,1) = 0
    ! End of force table array
    f,n_hole,fz,%force%   ! Apply force array
    !
    !solc,off             ! Solution controls OFF
    solc,on
    autots,on             ! Automatic time stepping
   deltim,.002,0.0005,0.01  ! Integration time step
    outres,basi,all
    time,.3
    solve
    finish
    !
    /post26
    nsol,2,4,u,z,uz4
    /title,PLATE TRANSIENT ANALYSIS- DISP VS TIME, BETA=%d_beta%
    plvar,2
    extrem,2
    finish
    !
    /post1
    set,,, ,,0.02915
    /title,PLATE TRANSIENT ANALYSIS
    /plopts,info,on
    /plopts,leg2,off
    pldisp,2
    /dsca,,1
    pldisp,2
    /focus,,3,3,0
    !antime,20,.05,,,1,2,0,1     ! Animate over time = 0 to 1
    finish
  *endif         ! if tran=1
  ! End of transient analysis
*endif         ! if complete=1
/show,term
!
 
  评论这张
 
阅读(2955)| 评论(1)
推荐 转载

历史上的今天

在LOFTER的更多文章

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2016