注册 登录  
 加关注
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

htbbzzg的博客

与朋友们分享 CAE 资料和经验

 
 
 

日志

 
 

ANSYS 入门教程 (18) - 几何建模实例 (a 弹簧和螺钉)  

2010-08-10 08:49:58|  分类: ANSYS 入门基础 |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

2.6 几何建模实例
2.6.1 弹簧
    按力学行为弹簧可分为压缩弹簧、拉伸弹簧、扭转弹簧及弯曲弹簧;按弹簧外形可分为螺旋弹簧、蝶形弹簧、环形弹簧和板簧等。
    仅就单个弹簧进行力学分析时,可采用 3D 实体单元进行模拟,以分析弹簧的各种力学行为及其参数;如果将弹簧与结构共同分析,可采用弹簧单元,其实常数可采用单个实体弹簧分析得到的参数或弹簧本身的出厂参数。
    圆柱形压缩弹簧和拉伸弹簧的节距不同,但建模方法是相同的。基本方法都是利用面沿路径拖拉创建体,ANSYS 命令众多,具体方法可以多种多样。

1. 整圈数圆柱形螺旋弹簧的建模
    整圈数时,弹簧的建模方法可先创建 1/2 螺旋线,然后利用对称性生成一圈的螺旋线;在螺旋线端部创建簧丝断面,然后沿路径拖拉该
面创建一圈簧身;利用体复制生成其它部分。

                ANSYS 入门教程 (18) - 几何建模实例 (a 弹簧和螺钉) - htbbzzg - htbbzzg的博客

     示例:

          !ex2.1A-整圈数圆柱形螺旋弹簧的几何建模
          finish  $ /clear  $ /prep7
          !1.定义弹簧参数-------------------------------------------------------------------------------------
          d=4                                             ! 簧丝直径
          c=8                                             ! 旋绕比,簧丝直径不同,旋绕比的范围也不相同
          n=10                                           ! 圈数(设为整数),即螺旋线的圈数
          dz=c*d                                         ! 弹簧中径,即螺旋线的直径
          t=dz/2.5                                       ! 节距 (螺距)
          *if,t,lt,d,then  $ t=d  $ *endif         ! 节距的最小值为簧丝直径,拉伸弹簧的 t=D
          !2.创建一圈螺旋线----------------------------------------------------------------------------------
          csys,1                                         ! 设置当前坐标系为柱坐标系
          k,1,dz/2,0,-t/2  $ k,2,dz/2,180     ! 创建两个关键点
          l,1,2                                            ! 创建半圈螺旋线
          csys,0                                         ! 设置直角坐标系
          lsymm,z,1  $ lsymm,y,2,,,,,1        ! 利用对称性生成另外半圈螺旋线
          nummrg,all $ cm,l1,line               ! 合并关键点,并将此两条线定义为组件 L1
          !3.在螺旋线端部创建簧丝截面------------------------------------------------------------------
          kwpave,1  $ wprota,,90               ! 移动工作平面并旋转
          cyl4,,,d/2                                     ! 创建直径为 D 的圆面(簧丝截面)
          !4.沿L1路径拖拉圆面创建体、复制体等-----------------------------------------------------
          vdrag,1,,,,,,l1                              ! 拖拉面创建体
          vgen,n,all,,,,,t                             ! 复制体 N 次
          nummrg,kp  $ wpcsys                 ! 合并关键点,并将工作平面归位

                ANSYS 入门教程 (18) - 几何建模实例 (a 弹簧和螺钉) - htbbzzg - htbbzzg的博客

 

2.   任意圈数圆柱形螺旋弹簧的建模
    当不为整圈数时,弹簧的建模方法可先创建螺旋线;在螺旋线端部创建簧丝断面,然后沿路径拖拉该面创建簧身。螺旋线每圈用 4 条线表达,即两关键点对应的角度为 90 度,当然也可改变此值,例如命令流中的 90 度改为 10 度等。

    此问题留给网友作为练习。

                ANSYS 入门教程 (18) - 几何建模实例 (a 弹簧和螺钉) - htbbzzg - htbbzzg的博客

 

2.6.2  螺纹
    螺纹联接是最为常用的联接形式。螺纹除有外螺纹和内螺纹之分外,螺纹可分为圆柱螺纹和圆锥螺纹,其中最常用的是圆柱螺纹。常用螺纹按牙形主要有普通螺纹、管螺纹、矩形螺纹、梯形螺纹和锯齿形螺纹等,其特点和应用各不相同。
    螺纹在几何模型的创建过程中其基本方法也是创建螺旋线、创建牙形截面、拖拉面创建体等步骤。而内外螺纹无非是略加修改参数即可,这里仅以螺栓联接中的螺杆为例介绍其建模过程,采用 GB5782-86-Md×L 系列螺栓,其螺栓几何尺寸和螺纹如图所示。

                ANSYS 入门教程 (18) - 几何建模实例 (a 弹簧和螺钉) - htbbzzg - htbbzzg的博客

    示例:

         ! ex2.2螺栓杆建模命令流
         Finish  $ /clear  $ /prep7
         ! 1.定义几何参数----------------------------------------------------------------------------
         d=20  $  l=60  $  b=46                      ! 公称直径 = 外螺纹大径、螺杆长度、螺纹长度
         p=2.5  $ dw=28.2  $ smax=30          ! 螺距、dw 最小值、S 最大值,可据公称直径查得
         kgc=12.5  $ c=0.8                            ! k公称值、c 的最大值
         refa=60                                            ! 齿形角 60°,标准螺栓采用值
         *afun,deg                                         ! 设置角度单位为:度
         h=0.5*p*cos(refa/2)/sin(refa/2)        ! 计算参数 H
         d1=d-2*5/8*h  $ d2=d-2*3/8*h          ! 外螺纹小径、外螺纹中径
         dbangl=30                                        ! 螺杆头部正六棱柱的倒角
         tkpd=30                                            ! 齿部螺旋线两关键点所对的圆心角度

         ! 2.创建螺旋线(采用分段螺旋线)------------------------------------------------------
         CSYS,1                                             ! 设置当前坐标系为柱坐标系
         n=(b-3*p/4)/p                                    ! 计算齿部螺旋线的总圈数
         TDEG=N*360                                    ! 总度数,即螺旋线的总旋转角度
         TDEG1=MOD(TDEG,TKPD)             ! 求余数,即以 TPKD 度为一点时余下的度数
         N0=(TDEG-TDEG1)/TKPD+1           ! 整 TPKD 度的数目,增加 1 点
         *DO,I,1,N0                                        ! 用循环创建关键点
             CTA=(I-1)*TKPD                          ! 求得 RΘ 坐标
             Z=p/360*CTA                               ! 求得 RZ 坐标
             K,I,d1/2,CTA,Z                             ! 创建关键点(柱坐标系下)
         *ENDDO                                           ! 结束循环
         *IF,TDEG1,LT,1.0E-2,THEN             ! 如果 N 为整数,则不创建非 TPKD 度点
         *ELSE                                               ! 否则,要创建此关键点
             N0=N0+1                                       ! 再增加最后的非 TPKD 度点
             CTA=CTA+TDEG1                       ! 求得最后一点的 RΘ 坐标
             Z=p/360*CTA                               ! 求得最后一点的 RZ 坐标
             K,N0,d1/2,CTA,Z                          ! 创建最后一个关键点
         *ENDIF
         *DO,I,1,N0-1  $ L,I,I+1  $ *ENDDO   ! 利用循环创建螺旋线
         CM,L1cm,LINE                                 ! 将上述线定义为组件 L1CM

                ANSYS 入门教程 (18) - 几何建模实例 (a 弹簧和螺钉) - htbbzzg - htbbzzg的博客
 

          ! 3.在螺旋线端部创建齿截面--------------------------------------------------------------
         CSYS,0                                     ! 设置直角坐标系
         km=kpinqr(0,14)                        ! 查得当前关键点最大号
         k,km+1,d1/2,,-3*p/8                   ! 创建 4 个关键点
         k,km+2,d1/2,,3*p/8  $ k,km+3,d/2,,p/16  $ k,km+4,d/2,,-p/16
         a,km+1,km+2,km+3,km+4          ! 由关键点创建齿截面
         VDRAG,1,,,,,,L1cm                    ! 拖拉齿截面创建体
         numcmp,all                                ! 压缩图素编号

                ANSYS 入门教程 (18) - 几何建模实例 (a 弹簧和螺钉) - htbbzzg - htbbzzg的博客

 

         ! 4.创建圆柱体(未考虑退刀槽)----------------------------------------------------------
         wpoff,0,0,-3*p/8          ! 移动工作平面
         cyl4,,,d1/2,,,,b             ! 创建圆柱体
         v1=vlinqr(0,14)           ! 查得当前体最大编号
         ! 5.创建部分螺杆的圆柱体及头部圆柱体-------------------------------------------------
         wpoff,,,b  $ cyl4,,,d/2,,,,l-b  $ v2=v1+1
         wpoff,,,l-b  $ cyl4,,,dw/2,,,,c  $ v3=v1+2
         ! 6.螺杆头部,正六边形棱柱-------------------------------------------------------------------
         rprism,c,kgc,6,,,smax/2  $ v4=v1+3

                ANSYS 入门教程 (18) - 几何建模实例 (a 弹簧和螺钉) - htbbzzg - htbbzzg的博客
 

          ! 7.螺杆齿部端倒角处理---------------------------------------------------------------------
          ! 以下创建两个圆锥体相减,形成空心锥体,再与螺杆齿部端体相减,作倒角
         wpcsys
         cone,d,d,-3*p/8,(d-d1)/2-3*p/8  $ cone,d1/2,d/2,-3*p/8,(d-d1)/2-3*p/8
         v5=vlinqr(0,14)  $ vsbv,v5-1,v5  $ v5=vlinqr(0,14)
         vsel,s,loc,z,0,2*p$vsel,a,,,v1  $ vsel,u,,,v5  $ cm,v2cm,volu
         vsel,a,,,v5  $ vsbv,v2cm,v5  $ allsel

                ANSYS 入门教程 (18) - 几何建模实例 (a 弹簧和螺钉) - htbbzzg - htbbzzg的博客

 

         ! 8.倒C处角,方向同上。-------------------------------------------------
         vsel,none$wpoff,,,l-3*p/8  $ cone,d,d,0,c  $ cone,dw/2-c,dw/2,0,c
         *get,v5,volu,0,num,min$v6=vlnext(v5)  $ vsbv,v5,v6
         *get,v5,volu,0,num,min  $ allsel
         vsbv,v3,v5

                ANSYS 入门教程 (18) - 几何建模实例 (a 弹簧和螺钉) - htbbzzg - htbbzzg的博客

 

         !  9.螺杆头倒角,即对正六棱柱倒角。采用球体相减完成--------------------------
         vsel,none  $ rq=smax/2/sin(dbangl)  $ wpoff,,,kgc-rq*cos(dbangl)
         sphere,rq,rq+kgc  $ *get,v5,volu,0,num,min  $allsel
         vsbv,v4,v5  $ wpcsys$numcmp,all

                ANSYS 入门教程 (18) - 几何建模实例 (a 弹簧和螺钉) - htbbzzg - htbbzzg的博客

 

         ! 10 粘接运算。如果不能粘接,则可通过调正布尔容差或将 TKPD 设置更小些,例如将
         ! 参数 TKPD=10,则可将所有体粘接在一起。建议采用后者,而不建议改变布尔容差。
         ! vglue,all   $ /view,1,1,1,1  $ /ang,1,-60,ys,1  $ vplot


    以上命令流可创建完整的螺杆,其它形式的螺杆或螺母均可采用类似的方法建模。

  评论这张
 
阅读(5994)| 评论(18)
推荐 转载

历史上的今天

在LOFTER的更多文章

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2016