注册 登录  
 加关注
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

htbbzzg的博客

与朋友们分享 CAE 资料和经验

 
 
 

日志

 
 

ANSYS 入门教程 (43) - 结构线性静力分析 (a)  

2010-09-03 07:26:33|  分类: ANSYS 入门基础 |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

第6章  结构线性静力分析

6.1   结构线性静力分析概述
6.2   桁架结构
6.3   梁结构
6.4   板壳结构
6.5   实体结构
6.6   杆梁壳体的连接处理
6.7   结构分析的特殊问题

 

6.1   结构线性静力分析概述

    结构线性静力分析的重要性:
        ★  结构线性静力分析最为常用。
        ★  设计规范基本上采用线弹性分析结构的内力。
        ★  是各种分析的基础。


    结构分析的四个基本步骤:
        ◆  创建几何模型
        ◆  生成有限元模型
        ◆  加载与求解
        ◆  结果评价与分析。

 

1.  创建几何模型
    ⑴  清除当前数据库
        ①  回到开始层:FINISH 命令。清除数据库的操作要在开始层。
        ②  清除数据库:/CLEAR 命令。开始新工作前清除数据库。
    ⑵  工作文件名与主标题
        ①  工作文件名:/FILNAME 命令。建议用户定义。
        ②  主标题:/TITLE 命令。用于在图形区显示。
        子标题可用  /STITLE  命令定义。
    ⑶  创建具体的几何模型

 

2.  生成有限元模型
    ⑴  定义单元类型、实常数和材料性质
        ①  定义单元类型,设置单元的 KEYOPT 的选项。
        ②  定义单元实常数,如有初应变时也应设置。
        ③  定义弹性模量,如为各项同性时只需定义 EX 即可。
        ④  定义质量密度,以便计算自重影响或惯性释放计算。
        ⑤  定义热膨胀系数等。
    此部分常常在创建具体的几何模型之前定义,以便在几何模型上施加荷载与约束。
    ⑵  定义网格划分属性
        ①  定义单元划分数目或大小。
        ②  定义单元划分类型和划分方式,如映射网格或自由网格等。
        ③  对几何模型实施网格划分。

 

3.  加载与求解
    ⑴  定义求解选项
        ①  进入求解层。有些荷载可以在前处理层施加,不必一定到求解层施加。
        ②  定义分析类型,ANSYS缺省分析类型为静态分析,也可省略。
        ③  定义求解选项,如输出、求解器等选项的设置。
    ⑵  加载
        ①  划分荷载步。
        ②  施加约束,约束可在几何模型上施加,也可在有限元模型上施加。
        ③  施加荷载,静力分析的荷载如集中荷载、分布荷载、温度、自重和旋转惯性力。对梁单元的分布荷载必须施加在有限元模型上。
    ⑶  求解

 

4.   结果评价与分析
    ①  进入通用后处理,一般不必进入时程后处理。
    ②  读入结果数据,如确定读入哪个荷载步的结果。
    ③  对结果处理,并图形显式和列表显示结果。
    ④  误差估计,仅 SOLID 和 SHELL 单元可考察网格密度对结果的影响。


 6.2   桁架结构

    桁架结构特点:
        ★  由若干杆件在两端用铰联结而形成的结构
        ★  各铰结点为无摩擦的理想铰
        ★  各杆轴线通过铰中心
        ★  荷载和支座反力作用在结点上
    模拟单元:LINK 系列(2D 和 3D)
    单元特点:
        ★只承受杆轴向的拉压,不承受弯矩
        ★节点只有平动自由度
        ★荷载:集中力和温度

 

一、  平面桁架

    如图平面桁架,设桁架中各杆件的面积均为 100 mm^2,材料弹性模量为 210GPa, 对此桁架进行静力分析。

                ANSYS 入门教程 (43) - 结构线性静力分析 (a) - htbbzzg - htbbzzg的博客

     命令流示例:

          !  EX6.1 平面桁架线性静力分析
          finish$/clear$/prep7
          et,1,link1  $ r,1,1e-4  $ mp,ex,1,2.1e11          ! 定义单元类型、实常数和材料性质
          k,1  $ k,2,2  $ k,3,3  $ k,4,4  $ k,5,6               ! 创建关键点
          k,6,2,-1  $ k,7,4,-1
          l,1,2  $ l,2,3  $ l,3,4  $ l,4,5  $ l,1,6  $ l,2,6      ! 创建线
          l,3,6  $ l,3,7  $ l,4,7  $ l,6,7  $ l,5,7
          fk,1,fy,-5000  $ fk,2,fy,-8000                           ! 在几何模型上施加荷载
          fk,3,fy,-6000  $ fk,4,fy,-8000
          dk,1,ux,,,,uy                                                    ! 在关键点 1 施加两个方向的约束,等效于 DK,1,ALL
          lesize,all,,,1                                                     ! 每根线划分 1 个单元,对 LINK1 必须如此
          lmesh,all                                                         ! 划分网格

          *afun,deg                                                       ! 定义三角函数的计算采用度,而不是弧度
          ref=asin(1/sqrt(5))                                          ! 求右端支座方向与竖直方向的夹角 REF
          nmodif,5,,,,ref                                                 ! 修改节点 5 的节点坐标系方向
          d,5,uy                                                             ! 节点 5 施加 Y 方向约束
          f,5,fy,-5000*cos(ref)                                       ! 在节点 5 按旋转后的节点坐标系施加荷载
          f,5,fx,-5000*sin(ref)                                        ! 这里将 5000 分解到旋转后的节点坐标系 X 和 Y 方向
          nmodif,2,,,,45                                                 ! 修改节点 2 的节点坐标系(转 45°)其上荷载随转动
          ftran$dtran                                                     ! 将荷载与约束传到有限元模型上(不是必须的)
          /pbc,f,,2  $ eplot                                             ! 显示荷载符号并在旁边标注荷载值
          finish  $ /solu  $ solve                                    ! 进入求解层,求解
          finish  $  /post1                                              ! 进入通用后处理

                ANSYS 入门教程 (43) - 结构线性静力分析 (a) - htbbzzg - htbbzzg的博客

 

                ANSYS 入门教程 (43) - 结构线性静力分析 (a) - htbbzzg - htbbzzg的博客

 

          pldisp,1                                 ! 显示变形图,并同时显示变形前形状
          /pnum,sval,1                         ! 在图上显示应力、内力等值
          etable,axst,ls,1                      ! 以单元应力定义单元表 AXST
          plls,axst,axst,0.5                   ! 显示单元应力,且显示比率为 0.5
          pletab,axst                            ! 用云图显示单元应力
          etable,axfor,smisc,1              ! 以单元轴力定义单元表 AXFOR
          plls,axfor,axfor,0.5                 ! 显示单元轴力,且显示比率为 0.5
          pletab,axfor                           ! 用云图显示单元轴力
          plesol,smisc,1                        ! 直接用云图显示单元轴力
          !列表显示结果
          prrsol  $ prnsol,u  $ prnld  $ presol,forc  $ presol,smisc,1

    需要注意以下几个问题:
          ①  斜向荷载的处理:可采用分解法将荷载分解为与节点坐标系平行的荷载,也可旋转节点坐标系进而施加整个荷载。建议采用分解法施加荷载。
          ②  斜向支承的处理:斜向支承(约束)处理需要旋转节点坐标系,但当同时具有荷载和约束时要注意,应避免所加非所想的情况,如上述例题中右端支承问题。
          ③  后处理技巧:线单元的内力一般需要单元表操作,图形显示可采用云图和线性化图两种方式,而标注结果值时采用云图可使结果更加直观。

 

二、  空间桁架

    建模技术:
        ★ 分析构成规律
        ★ 利用图素复制命令
        ★ 注意消除重合图素
    如图一吊车梁桁架,采用 N 型万能杆件拼组而成,吊重为 600kN 且在跨中 16m 范围内的两个对应上弦节点上移动。在下平纵联平面内,一端支座固定,其中一个为固定,另外一个横向可动;另外一端支座纵向可动,但与固定支座位于一侧的支座横向固定。假设节点板与螺栓等重量为杆件重量的 7% 且分布在杆件上,活载冲击系数为 1.1。工作状态横向风压强度为 500Pa,风力计算按主桁一侧轮廓面积乘以填充系数,填充系数取为 0.4,且均匀分布在上下弦节点上。要求计算结构杆件最大内力与挠度。

                ANSYS 入门教程 (43) - 结构线性静力分析 (a) - htbbzzg - htbbzzg的博客

 

                ANSYS 入门教程 (43) - 结构线性静力分析 (a) - htbbzzg - htbbzzg的博客

 

        !  EX6.2 N 型万能杆件桁架
        finish  $ /clear  $ /prep7
        !  ①  定义单根杆件的面积参数
        arean1=2330e-6  $ arean3=1670e-6  $ arean45=1150e-6  $ sl=2.0
        !  ②  定义单元类型、实常数及材料性质
        et,1,link8  $ r,1,2*arean1  $ r,2,3*arean1  $ r,3,4*arean1  $ r,4,3*arean3
        r,5,4*arean3  $ r,6,4*arean45  $ r,7,2*arean45  $ mp,ex,1,2.1e11
        mp,dens,1,7850*1.07
        !  ③  创建几何模型 - 主桁
        k,1  $ k,2,sl  $ k,3,2*sl  $ kgen,2,all,,,,sl
        l,1,2  $ l,2,3  $ l,4,5  $ l,5,6  $ l,1,4  $ l,2,5  $ l,3,6  $ l,1,5
        l,5,3  $ lgen,6,all,,,2*sl  $ nummrg,all  $ lgen,2,all,,,,,sl
        !  ③ 创建几何模型---上下平纵联
        lsel,none  $ k,101,,,sl  $ k,102,sl,,sl  $ k,103,2*sl,,sl
        l,1,101  $ l,2,102  $ l,3,103  $ l,1,102  $ l,3,102  $ lgen,6,all,,,2*sl  $ lgen,2,all,,,,sl
        lsel,all  $ l,1,16  $ *get,l1,line,,num,max  $ lgen,13,l1,,,sl
        nummrg,all  $ numcmp,all

        !  ④  赋予线属性 - 2N1 类杆件
        lsel,s,loc,x,0,4  $ lsel,a,loc,x,20,24  $ lsel,r,tan1,y  $ lsel,r,tan1,z
        cm,l2n1,line  $ latt,1,1,1
        !  ④  赋予线属性---3N1类杆件
        lsel,s,loc,x,4,8  $ lsel,a,loc,x,16,20  $ lsel,r,tan1,y  $ lsel,r,tan1,z
        cm,l3n1,line  $ latt,1,2,1
        !  ④  赋予线属性 - 4N1 类杆件,并将弦杆定义为组件 XG
        lsel,s,loc,x,8,16  $ lsel,r,tan1,y  $ lsel,r,tan1,z  $ cm,l4n1,line  $ latt,1,3,1
        cmsel,a,l3n1  $ cmsel,a,l2n1  $ cm,xg,line
        !  ④  赋予线属性 - 3N3类杆件
        lsel,s,loc,x,6,18  $ cmsel,u,xg  $ lsel,u,tan1,y  $ lsel,u,tan1,x
        latt,1,4,1  $ cm,l3n3,line
        !  ④  赋予线属性---4N3类杆件
        lsel,s,loc,x,0,6  $ lsel,a,loc,x,18,24  $ cmsel,u,xg  $ lsel,u,tan1,y  $ lsel,u,tan1,x
        latt,1,5,1  $ cm,l4n3,line
        !  ④  赋予线属性 - 4N4 或 4N5 类杆件
        lsel,s,loc,x,0,2  $ lsel,a,loc,x,22,24  $ lsel,r,tan1,x  $ lsel,r,tan1,z
        latt,1,6,1  $ cm,l4n4,line  $ allsel
        !  ④  赋予线属性 - 2N4 或 2N5 类杆件
        cmsel,u,xg  $ cmsel,u,l3n3  $ cmsel,u,l4n3  $ cmsel,u,l4n4  $ latt,1,7,1  $ allsel

        !  ⑤  划分单元
        lesize,all,,,1  $ lmesh,all
        !  ⑥  施加约束
        ksel,s,loc,x,0  $ ksel,r,loc,y,0  $ ksel,r,loc,z,0  $ dk,all,all
        ksel,s,loc,x,0  $ ksel,r,loc,y,0  $ ksel,r,loc,z,sl  $ dk,all,uy
        ksel,s,loc,x,24  $ ksel,r,loc,y,0  $ksel,r,loc,z,0  $ dk,all,uy,,,,uz
        ksel,s,loc,x,24  $ ksel,r,loc,y,0  $ ksel,r,loc,z,sl  $ dk,all,uy
        allsel  $ finish
        !  ⑦  进入求解层,施加荷载,定义荷载步等
        /solu  $ acel,,9.8  $ solve                                              ! 自重为第 1 荷载步
        acel,,0  $ p1=500*sl  $ nsel,s,loc,z,0  $ f,all,fz,p1
        nsel,u,loc,x,1,23  $ f,all,fz,p1/2  $ nsel,all  $ solve         ! 风载为第 2 荷载步
        *do,i,1,5  $ fdele,all,all
        nsel,s,loc,x,(i+1)*sl  $ nsel,r,loc,y,sl
        f,all,fy,-300000  $ nsel,all  $ solve  $ *enddo                 ! 移动荷载定义为后续荷载步
        finish

        !  ⑧  进入后处理,定义荷载工况并组合,输出图片和文本文件
        /post1  $ set,list  $ *do,i,1,7  $ lcdef,i,i  $ *enddo
        lcfact,1,1.0  $ lcfact,2,1.0  $ *do,i,3,7  $ lcfact,i,1.1  $ *enddo
        lczero  $ lcase,1  $ lcoper,add,2
        *do,i,3,7  $ j=i+5  $ lcoper,add,i  $ lcwrite,j,lc%j%  $ lcoper,sub,i  $ *enddo
        /output,resfile0,txt  $ /view,1,1,2,3  $ /ang,1,-6,xs,1
        etable,stre,ls,1  $ etable,forc,smisc,1
        *do,ic,1,12  $ /output,resfile%ic%,txt  $ lczero  $ lcase,ic  $ etable,refl
        /show,jpeg  $ pletab,stre  $ pldisp,1  $ /show,term
        /com,--------荷载工况或组合%ic%的结果---------
        pretab  $ prrsol  $ prnsol,u  $ *enddo  $ /output

       

    该例中需要注意以下几个问题:
        ①  建模:创建几何模型时,可采用先建局部可重复模型,然后利用复制功能创建相同部分,最后消除重合关键点和线;也可利用 APDL 中的循环语句直接创建各个关键点和线,但需要较好的控制技巧,以便编程创建几何模型。在创建几何模型过程中,可给线赋予材料属性,也可在几何模型创建完成后赋予属性。
        ②  载荷工况:具有移动载荷时,将载荷划分不同的载荷步求解,后处理时再利用载荷工况处理技术进行组合并输出。该项操作在计算或求解时要有一定的规划,以便后处理时使用各载荷步的结果。
        ③  图素选择与组件:图素选择是 ANSYS 的一大技巧,编制命令流文件必须掌握该技巧。图素的选择有很多选项,需根据几何模型的特点灵活运用。在选择某些图素后可定义为元件,在后续选择中可适当利用。

  评论这张
 
阅读(2898)| 评论(5)
推荐 转载

历史上的今天

在LOFTER的更多文章

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2016