注册 登录  
 加关注
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

htbbzzg的博客

与朋友们分享 CAE 资料和经验

 
 
 

日志

 
 

ANSYS 入门教程 (36) - 分析类型与求解控制选项 (e)  

2010-08-27 06:43:40|  分类: ANSYS 入门基础 |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

4.6   时变结构的多荷载步求解

    时变结构指其自身随时间变化而变化,一般可分为三类:
        快速时变结构:荷载和结构迅速变化,其特点是必须考虑结构惯性影响。如车桥耦合和可展式航天器等问题。
        慢速时变结构:结构和荷载随时间变化缓慢,可用离散的时间近似处理,形成一系列的时不变结构的分析。如施工过程结构及其荷载的变化。

        超慢速时变结构:结构和荷载的变化极其缓慢,如工程结构服役期间的健康状态问题等。
    利用荷载步文件求解(LSSOLVE)和荷载步直接求解(连续的 SOLVE)有时是不同的,如考虑结构变化(R 或 MP 命令)、生死单元等时荷载步文件无法实现,而荷载步直接求解则可解决此类问题,这里根据计算讨论其异同等问题。

一、  结构不变时的求解

    结构变化是指材料特性的改变、实常数的改变、边界条件的改变等,结构不变就是指上述参量在整个加载过程中不变化。
    当结构不变时,对线性分析或非线性分析,无论是荷载步文件求解或是荷载步直接求解,其结果一致,且结果总是“后续荷载步在前步的基础上计算”。
    如图 A 所示一悬臂梁受两个集中荷载作用,按线性静态分析采用两种求解方法,支座竖向反力与悬臂端竖向位移的关系曲线如图 B 所示;按几何非线性静态分析采用两种求解方法,所得曲线如图 C 所示;荷载步和子步与时间的关系如图 4D 所示。

    命令流示例:

        !  EX4.20  线性/非线性静态分析的荷载步直接求解
        finish  $ /clear  $ /prep7
        l=1000  $ b=10  $ h=20                         ! 定义长度、截面宽度和高度参数
        et,1,beam3                                            ! 定义单元类型
        mp,ex,1,2.0e5  $ mp,prxy,1,0.3             ! 定义材料性质
        r,1,b*h,b*h*h*h/12,h                              ! 定义实常数
        k,1  $ k,2,l  $ l,1,2                                 ! 创建关键点与线
        lesize,all,,,10  $ lmesh,all                      ! 定义单元划分个数并划分单元
        d,1,all                                                    ! 施加固定约束
        /solu  $ antype,0                                   ! 进入求解层,定义分析类型为静态分析
        !nlgeom,on                                           ! 关闭大变形则为线性分析,打开则为非线性分析
        outres,all,all                                          ! 输出所有荷载步及子步的结果
        autots,off                                              ! 关闭自动时间步(为方便对比结果数据)
        time,1  $ nsubst,10                               ! 定义第 1 荷载步时间为 1,子步数为 10 个
        f,2,fy,-2000  $ solve                              ! 施加集中力 P1=2000,并求解
        time,2  $ nsubst,20                               ! 定义第 2 荷载步时间为 2,子步数为 20 个
        f,7,fy,-4440  $ solve                              ! 加集中力 P2=4440,并求解
        finish  $ /post26                                    ! 进入后时间处理

        nsol,2,2,u,y                                           ! 定义变量 2 为节点 2 的 Y 向位移
        rforce,3,1,f,y                                         ! 定义变量 3 为单元 1 的节点 1 的 Y 向反力
        prod,4,2,,,,,,-1                                      ! 变量数值计算,即将变量 2 乘 -1(变符号了)
        /axlab,x,Uy                                            ! 定义曲线的 X 轴标识符号
        /axlab,y,Fy                                            ! 定义曲线的 Y 轴标识符号
        xvar,4$plvar,3                                      ! 以变量 4 为 X 轴,绘制变量 3
        prvar,3,4                                              ! 列表输出变量 3 和变量 4

                ANSYS 入门教程 (36) - 分析类型与求解控制选项 (e) - htbbzzg - htbbzzg的博客

 

二、  结构变化-材料性质或实常数变化时的求解

    一般结构材料性质随时间的变化可以忽略,除非与温度相关的材料。而结构构件的实常数可能会随时间变化,如钢管混凝土施工(先安装空钢管,然后在钢管中浇筑混凝土)。这种时变结构的求解比较困难,即在材料性质或实常数变化时,如何才能实现“后续荷载步在前步的基础上计算”这样的问题呢?
    按照常规方法,虽然可以改变材料性质或实常数,但不能达到所预期的结果,如直接利用前面的重启动分析、初应力分析、荷载步直接法或荷载步文件法等均不能达到目的,不管是线性分析或是非线性分析。因为重启动分析本质上是一种在某个位置开始的继续分析,在某种程度上与连续求解相同;而初应力问题是作为荷载施加到结构上的,并不是保持在结构的应力或变形;荷载步文件法和荷载步直接法虽有不同,但也不能解决结构这种变化时的问题。

    例如,图所示的悬臂梁,如果在第 2 荷载步中利用 MPCHG 命令(或直接用MP命令)改变单元的材料号,计算分析在第 1 荷载步结果正确,即在材料号 Mat1 下作用有 P1 荷载的解;但在第 2 荷载步,结果就成为在材料号 Mat2 下作用有(P1+P2)荷载的解,而不是在 P1(对应 Mat1)解的基础上施加 P2(对应Mat2)的解。
    为达到要求的目的,可以采用重叠单元和生死单元实现这种结构变化的求解。重叠单元就是在两个节点(如 I 和 J)之间生成两个独立的单元,可以对这两个单元赋予不同的材料或实常数属性;同时再利用生死单元模拟变化过程,就可实现这个目的。

                ANSYS 入门教程 (36) - 分析类型与求解控制选项 (e) - htbbzzg - htbbzzg的博客

 

    改变材料性质时的求解
    以悬臂梁为例,设结构截面不变,在 P1 荷载作用时材料的弹性模量为 E0;之后材料弹性模量变为 E1 且又增加了 P2 作用。
    常规计算结果如图中的 “直接解”,而采用重叠单元和生死单元的计算结果如图中的 “重叠单元解”:

                    ANSYS 入门教程 (36) - 分析类型与求解控制选项 (e) - htbbzzg - htbbzzg的博客

 

    命令流如下:

        !  EX4.22  改变材料性质的求解 - 利用重叠单元和生死单元
        finish  $ /clear  $ /prep7
        !  定义参数、单元类型、材料特性 1 和材料特性 2、实常数等
        l0=1000  $ b0=10  $ h0=20  $ e0=2.0e5  $ a0=b0*h0  $ i0=b0*h0*h0*h0/12  $ coef1=3
        et,1,3  $ mp,ex,1,e0  $ mp,prxy,1,0.3  $ mp,ex,2,coef1*e0  $ mp,prxy,2,0.3  $ R,1,a0,i0,h0
        k,1  $ k,2,l0  $ l,1,2  $  lesize,all,,,10  $ lmesh,all                                 ! 创建几何模型并划分单元
        egen,2,0,all,,,1  $ d,1,all                                                                      ! 复制单元,节点号不变,材料号 +1
        /solu  $ antype,0  $ nlgeom,on  $ autots,off                                        ! 进入求解层,打开大变形等
        outres,all,all  $ nropt,full                                                                      ! 输出选项,定义完全 NR 法(生死单元必须的)
        time,1  $ nsubst,10  $ f,2,fy,2000                                                        ! 荷载步 1 的子步数,在悬臂端施加荷载 2000N
        esel,s,mat,,2  $ ekill,all  $ allsel                                                           ! 杀死材料号为 2 的所有单元
        solve                                                                                                    ! 求解第 1 荷载步
        time,2  $ esel,s,mat,,2  $ ealive,all                                                       ! 荷载步 2,激活被杀死的单元
        allsel  $ f,7,fy,4440  $ nsubst,20                                                          ! 施加荷载,定义子步数
        solve                                                                                                    ! 求解第 2 荷载步
        !  以下为进入时间后处理定义变量、变量计算及结果查看等
        finish  $ /post26  $ nsol,2,2,u,y  $ nsol,3,2,u,x  $ nsol,4,7,u,y  $ nsol,5,7,u,x
        rforce,6,1,f,y  $ rforce,7,1,m,z  $ prvar,2,3,4,5,6,7

        prod,8,6,,,,,,-1  $ xvar,2  $ plvar,8

 

三、  结构变化 - 边界条件变化时的求解

    当结构边界条件变化时,情况较材料或实常数变化更为复杂,也需要特殊处理才能得到“后续荷载步在前步的基础上计算”这样的结果。
    可采用两种方法,其一是约束位移法,其二是生死单元法。
    约束位移法的基本思路是:
        ① 对边界条件改变前的结构求解,可获得边界条件改变节点的某个自由度解;
        ② 对上述结构施加约束及约束位移,使得该约束对以前结果没有影响 (取上一步的位移结果作为约束即可,不能改变上一步位移的计算结果)。此步可求解也可不求解而直接进入下一荷载步。此步实质上就是在结构变形完毕后施加约束,多个约束改变时依然如此。
    如果边界条件是减少约束,此时应施加所获得的约束反力。
        ③ 继续后续荷载步求解。
        生死单元因只能“杀死”或“激活”单元,而无法对节点实施此操作,所以只能用刚性单元模拟边界条件,杀死该单元或激活单元以实现增加或减少约束。但生死单元法没有约束位移法简便而直观。

    下面以悬臂梁为例,给出增加支座的求解过程。
        !  EX4.24  边界条件变化时的求解
        finish  $ /clear  $ /prep7
            ! ① 创建模型 - 定义单元类型、材料性质、实常数、几何模型和有限元模型
        et,1,beam3  $ mp,ex,1,2.1e5  $ mp,prxy,1,0.3  $ r,1,100,10**4/12,10
        k,1  $ k,2,1000  $ l,1,2  $ esize,100  $ lmesh,all  $ d,1,all         !  约束节点 1 所有自由度
            ! ② 第 1 荷载步的求解 - 线性静力
        /solu  $ antype,0  $ outres,all,all  $ autots,off
        time,1  $ nsubst,5  $ f,2,fy,-10.0  $ solve
            ! ③ 第 2 荷载步的求解 - 仅施加了约束位移(Uy(7) 为节点 7 在第一个载荷步时的竖向位移,即新增约束不应改变上一步的结果)
        ! KBC 的设置对最终结果没有影响,但可观察各子步中位移和内力的变化
        time,2  $ d,7,uy,uy(7)  $ kbc,1  $ nsubst,5  $ solve
            ! ④ 后续荷载步的计算
        time,3  $ kbc,0  $ f,11,fy,-12.0  $ nsubst,6  $ solve
            ! ⑤ 通用后处理过程
        finish  $ /post1

        set,1,last  $ pldisp,1
        etable,mi,smisc,6  $ etable,mj,smisc,12  $ plls,mi,mj,-1  $ pretab,mi,mj
        set,2,last  $ pldisp,1  $ etable,refl  $ plls,mi,mj,-1  $ pretab,mi,mj
        set,3,last  $ pldisp,1  $ etable,refl  $ plls,mi,mj,-1  $ pretab,mi,mj
        ! 时间后处理过程
        /post26  $ nsol,2,2,u,y  $ rforce,3,1,f,y  $ rforce,4,7,f,y
        add,5,3,4,,,,,1,1  $ prod,6,2,,,,,,-1  $ plvar,6  $ plvar,3,4,5

 

    Time = 1 的位移结果

                ANSYS 入门教程 (36) - 分析类型与求解控制选项 (e) - htbbzzg - htbbzzg的博客
  

     Time = 1 的应力结果

                ANSYS 入门教程 (36) - 分析类型与求解控制选项 (e) - htbbzzg - htbbzzg的博客
 

     Time = 2 的应力结果 (此时应该不变)

                ANSYS 入门教程 (36) - 分析类型与求解控制选项 (e) - htbbzzg - htbbzzg的博客
 

     Time = 3 的应力结果 (由于增加了载荷,结果有变化)

                ANSYS 入门教程 (36) - 分析类型与求解控制选项 (e) - htbbzzg - htbbzzg的博客
 

     最大位移随时间 (载荷步) 的变化曲线

                ANSYS 入门教程 (36) - 分析类型与求解控制选项 (e) - htbbzzg - htbbzzg的博客
  评论这张
 
阅读(1777)| 评论(0)
推荐 转载

历史上的今天

在LOFTER的更多文章

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2016