注册 登录  
 加关注
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

htbbzzg的博客

与朋友们分享 CAE 资料和经验

 
 
 

日志

 
 

ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体)  

2010-08-13 11:30:59|  分类: ANSYS 入门基础 |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

2.6.6   型钢
    型钢种类较多,但其建模相对齿轮建模要简单的多。其方法是利用自底向上创建截面,然后沿着某个路径线拖拉截面成体。如图为工字钢、槽钢及不等边角钢的几何尺寸。

                ANSYS 入门教程 (21) - 几何建模实例 (d 型钢) - htbbzzg - htbbzzg的博客
 

     1.   热轧普通工字钢(GB706-65)
         !  EX2.6a  工字钢实体建模
         finish  $ /clear  $ /prep7
         h=360  $ b=136  $ d=10  $ t=15.8  $  r=12          ! 高度、翼缘宽度、腹板厚度、平均翼厚、内圆弧半径
         xd=1/6  $ r1=r/2                                                   ! 翼缘斜度及翼缘端圆弧半径(此二参数自动确定)
         l=300                                                                    ! 工字钢长度(任意)
         t1=t-(b-d)/4*xd                                                      ! 翼缘端部厚度(倒角前),便于建模
         t2=t+(b-d)/4*xd                                                     ! 翼缘根部厚度(倒角前),便于建模
         k,1$k,2,d/2  $ k,3,d/2,h/2-t2                                 ! 创建关键点(1/4 截面关键点)
         k,4,b/2,h/2-t1  $ k,5,b/2,h/2  $ k,6,0,h/2
         *do,i,1,5  $ l,i,i+1  $ *enddo                                  ! 创建线,形成1/4截面的线
         l,1,6  $ lfillt,2,3,r  $ lfillt,3,4,r1                               ! 封闭线,并倒角
         al,all                                                                     ! 由上述线创建 1/4 截面
         arsym,y,all  $ arsym,x,all                                      ! 对称生成全部截面
         aadd,all                                                                ! 将 4 个面相加生成一个面
         !可合并一些线,以显简洁(也可不合并)
         lsel,s,loc,y,-h/2  $ lcomb,all  $ lsel,s,loc,y,h/2  $ lcomb,all
         lsel,s,loc,x,-d/2  $ lcomb,all  $ lsel,s,loc,x,d/2  $ lcomb,all  $ allsel
         numcmp,all                                                          ! 压缩图素编号
         voffst,1,l                                                              ! 利用面偏置命令创建实体

                ANSYS 入门教程 (21) - 几何建模实例 (d 型钢) - htbbzzg - htbbzzg的博客
 

          !  对于曲线也可以采用拖拉方式创建实体
         local,12,1,l,,,,-90  $ *get,kp0,kp,0,num,max
         k,kp0+1,l,-180  $ k,kp0+2,l,0  $ l,kp0+1,kp0+2  $ *get,l0,line,0,num,max
         vdrag,1,,,,,,l0                            ! 沿路径线 L0 拖拉 A1 创建实体

                ANSYS 入门教程 (21) - 几何建模实例 (d 型钢) - htbbzzg - htbbzzg的博客

 

2. 热轧普通槽钢(GB707-88)- 略,自己做


3. 热轧不等边角钢(GB9788-88)- 略,自己做


4. 钢轨
    钢轨分为轻型和重型两种,其中重型钢轨主要有 75kg/m、60kg/m、50kg/m、45kg/m、43kg/m 及 38kg/m,各种钢轨除尺寸有差别外,其结构也存在些微差别,且在同级钢轨中因标准不同也有差异。下面以当前 60kg/m 主型轨的建模过程介绍如下,其结构参数如图所示。
    在一般标准或教科书中,钢轨的尺寸特别多,但能够确定钢轨截面的结构尺寸数量有限,其它尺寸均可由结构尺寸求得,可谓“导出”尺寸。 用结构尺寸建模可有多种方法,例如可采用与 AutoCAD 类似的绘制过程,即可通过作辅助线确定各个圆心等,然后删除多余的线。本例通过计算和作图相结合创建钢轨截面。

ANSYS 入门教程 (21) - 几何建模实例 (d 型钢) - htbbzzg - htbbzzg的博客
 
         !  EX2.6D  60kg/m 钢轨实体建模
         ! 修改参数可用于 75kg/m 和 45kg/m两种,而 50kg/m 和 43kg/m 则略需修改
         finish  $ /clear  $ /prep7
         !  1. 定义参数-------------------------------------------------------------------------------
         h1=30.5  $ h2=48.5  $ h3=48.5                                               ! 高度参数
         b1=45.75  $ b2=29.25  $ b3=16.5  $ b4=36.5  $ b5=10          ! 宽度参数
         xd1=1/3  $ xd2=1/9  $ xd3=1/3  $ xd4=1/20                             ! 斜度参数
         r0=400  $ r1=2  $ r2=4  $ r3=40  $ r4=20  $  r5=25                 ! 圆弧半径参数
         r6=8  $ r7=13  $ r8=80  $ r9=300  $ r10=2
         fai=43                                                                                       ! R6 圆心角
         h=h1+2*h2+h3                                                                          ! 钢轨全高
    补充该命令流,试完成操作。
ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体) - htbbzzg - htbbzzg的博客
 
2.6.7   桥墩
    常用桥墩按截面形式分为矩形桥墩、圆形桥墩、圆端型桥墩、尖端型桥墩和双柱式桥墩,几何上多为圆柱体、长方体及棱柱体的组合,创建模型相对容易。而高墩常用的截面形式有圆形空心、双圆孔空心、圆端型空心、圆端型中间设纵隔板空心、矩形空心、矩形中间设纵隔板空心等,下面结合两种桥墩说明建模过程。
    1.   双线圆端型桥墩
    图为某铁路双线整孔简支箱形梁桥墩,箱梁跨度为40m。其建模难点在于托盘中的锥体部分,可采用自底向上和自顶向下相结合的方法,命令流及解释如下。
                ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体) - htbbzzg - htbbzzg的博客
 
         !Ex2.7A 铁路双线整孔简支箱形梁桥墩实体建模
         finish  $ /clear  $ /prep7
         !  1. 定义参数----------------------------------------------------------------------------------
         lcap=10.6  $ wcap=3.8  $ hcap=0.4                    ! 顶帽长度(横桥向)、顶帽宽度(顺桥向)、顶帽高度
         capfi=0.05  $ hwsd=0.07                                     ! 顶帽倒角高度与宽度、流水坡高度
         hbs=0.4  $ lbs=1.6  $ wbs=3.0                            ! 垫石高度、垫石长度(横桥向)、垫石宽度(顺桥向)
         dbs=4.5                                                              ! 两垫石中心距离(横桥向)
         htray=1.4                                                            ! 托盘高度
         tpier=2.7  $ wpier=8.5  $ hpier=3.0                     ! 墩厚、墩宽、墩高
         ocap=0.2                                                            ! 顶帽的净边(横桥和顺桥向相同)
         !  2. 创建顶帽及排水坡体(1/4 几何体)--------------------------------------------------
         blc4,,,wcap/2,lcap/2,hcap                                   ! 创建顶帽长方体
         rx1=(wcap/2-capfi)/wcap*2                                 ! 计算收台比例 RX
         ry1=(lcap/2-capfi)/lcap*2                                    ! 计算收台比例 RY
         vext,2,,,,,capfi,rx1,ry1                                         ! 延伸面 2 创建 5cm 倒角体
         k,30,, dbs/2+lbs/2, hcap+capfi                           ! 创建流水坡上的关键点,然后创建体
         k,31,, dbs/2+lbs/2, hcap+capfi+hwsd
         k,32,,, hcap+capfi+hwsd
         v,11,12,30,31  $ v,9,10,32,30,11,31                  ! 创建流水坡几何体
                ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体) - htbbzzg - htbbzzg的博客
 
         !  3. 创建支承垫石---------------------------------------------------------------
         wpoff,,,hcap+capfi                                     ! 移动工作平面
         blc4,,dbs/2-lbs/2,wbs/2,lbs,hbs+capfi        ! 创建支承垫石(侵入流水坡)
         vadd,all$numcmp,all                                  ! 体相加,且压缩图素编号
         !  4. 创建墩身----------------------------------------------------------------------------------
         wpcsys  $ wpoff,,,-htray                             ! 移动工作平面
         blc4,,,tpier/2,wpier/2-tpier/2,-hpier             ! 创建非圆柱部分
         cyl4,,wpier/2-tpier/2,tpier/2,0,,90,-hpier     ! 创建圆柱部分
         vadd,2,3                                                    ! 体相加
         !  5. 创建托盘-采用自底向上方法-------------------------------------------------------
         !  创建 3 个关键点(位于净边上)
         k,50,wcap/2-ocap  $ k,51,wcap/2-ocap,lcap/2-ocap  $ k,52,0,lcap/2-ocap
         v,2,50,29,28,52,51,30,31                          ! 创建棱柱体
         v,36,52,31,36,51,30                                  ! 创建弧部分体
         vadd,all
         !  6. 创建整个桥墩-----------------------------------------------------------------------------
         vsymm,x,all  $ vsymm,y,all  $ vadd,all  $ numcmp,all
 
                ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体) - htbbzzg - htbbzzg的博客
 
2.6.8   桥台
    铁路桥台形式主要有 U 型桥台、T 型桥台、耳墙式桥台和埋式桥台等四种类型,而公路桥台常用形式有 U 型桥台、埋式桥台、八字式或一字式桥台、框架桥台(肋板或柱组成)等。桥台在几何上多为长方体和圆柱体的组合,一般采用自上而下方法建模较方便,这里仅以铁路 T 型桥台为例,说明其建模过程。
    单线 T 型桥台的构造如图所示(参考叁桥 (89) 4025)。
         !  EX2.8   铁路单线 T 型桥台
         finish$/clear$/prep7
         !定义参数--------------------------------------------------------------------------------------
         b0=5$b1=3.9$b2=2.2$b3=3.4$b4=3.8$b5=5.0$b6=2.6$b7=4.2
         d0=1.1$d1=5.65$d2=2.0$d3=0.2$d4=3.55$d5=2.4$d6=4.35$d7=3.3$d8=0.2
         h1=1.58$h2=6.0$h3=1.0$h4=1.0$h5=2.38$h6=0.5$h7=1.1$h8=0.65
         h9=h1+h2-h5-h6-h7
                ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体) - htbbzzg - htbbzzg的博客

          !  创建台身各部实体-----------------------------------------------------------------------
         blc4,,,d6,b7/2,h4  $ blc4,d6,,d7,b5/2,h4                                     ! 创建第一层基础
         wpoff,d6-d4,,h4  $ blc4,,,d4,b6/2,h3  $ blc4,d4,,d5,b4/2,h3       ! 创建第二层基础
         wpoff,d8,,h3  $ blc4,,,d4+d3-d8,b2/2,h1+h2-h8                         ! 创建前墙
         blc4,d4+d3-d8,,d2,b3/2,h9                                                         ! 创建部分台身
         wpoff,d4-d8,,h9+h7  $ blc4,,,d2+2*d3,b0/2,h6                           ! 创建台帽
         vext,32,,,,,h7,,(b0/2-d3)/b3*2                                                     ! 创建托盘
         wpoff,d3,,h6  $ blc4,,,d2-d0,b2/2,h5-h8                                     ! 创建部分台身(前端)
         wpcsys
         x1=d1+d0-d2-d3-d6  $ z1=h4+h3+h2+h1-h8  $ wpoff,-x1,,z1
         x2=d1+d0-d2-d3-d4+d8  $ blc4,,,x2,b2/2,-(h1-h8)                     ! 创建部分台身(台尾)
         v,69,71,33,70,72,34                                                                  ! 创建部分台身(台尾)
         !  道碴槽建模(常规尺寸)---------------------------------------------------------
         cswpla,12,0  $ k,500$k,501,,b2/2  $ k,502,,b1/2,0.13  $ k,503,,b1/2,h8
         k,504,,b1/2-0.14,h8  $ k,505,,b1/2-0.245,h8-0.3  $ k,506,,,h8-0.3
         a,500,501,502,503,504,505,506                                              ! 创建道碴槽断面
         *get,a1,area,0,num,max                                                           ! 得到该断面面号
         voffst,a1,d1                                                                              ! 创建道碴槽
         vsymm,y,all  $ vadd,all  $ numcmp,all                                      ! 形成整个桥台
         !  可将能够合并的面合并,以显简捷。

                ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体) - htbbzzg - htbbzzg的博客

 

                ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体) - htbbzzg - htbbzzg的博客

 

2.6.9   异体
1.  上圆下方柱建模
    圆顶方底的几何实体建模可采用蒙皮创建面,然后由面创建体。
         !  Ex2.9A 上圆下方体的建模
         finish  $ /CLEAR  $ /PREP7
         N=7  $ a=4                                                ! 定义多边形边数和多边形外接圆半径
         rpoly,n,,a                                                   ! 创建正多边形
         lsel,none                                                   ! 创建由N条线形成的圆面
         k,n+1,,,3*a  $ circle,n+1,a/2,,,,n  $ al,all  $  allsel
         *do,i,1,n  $ ASKIN,i,i+n  $ *enddo              ! 蒙皮创建各个侧面
         VA,all                                                        ! 创建体
         !  如果底面是正方形,也可直接采用 V 命令创建体

                ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体) - htbbzzg - htbbzzg的博客

 

2.   斜向圆台建模
    圆台的两个端面圆心不重合,半径不相等即形成斜向圆台。这种斜向圆台在金属结构中时有采用,例如薄壁管件或其接头等。其建模方法可采用蒙皮或采用面的延伸形成,例如:
         !  EX2.9B  斜向圆台建模
         finish  $ /clear  $ /prep7
         r0=3  $ r1=2  $ h=4                              ! 定义圆台底面半径、顶面半径及台高
         ! 采用蒙皮方法创建圆台
         cyl4,,,r0                                                ! 创建圆台底面
         wpoff,r1,,h  $ cyl4,,,r1                          ! 移动工作平面,并创建圆台顶面
         *do,i,1,4  $ askin,i,i+4  $ *enddo          ! 蒙皮创建台身侧表面
         va,all                                                   ! 由面创建体
         !  采用斜向延伸创建圆台
         vgen,1,1,,,,3*r0,,,,1                            ! 移动前一圆台
         wpcsys  $ cyl4,,,r0                             ! 恢复工作平面,并创建圆台底面
         vext,7,,,r1,,h,r1/r0,r1/r0                     ! 延伸面 7 创建圆台(圆面移到 R1,,H,且按比例缩小)

                ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体) - htbbzzg - htbbzzg的博客

 

3.   函数方程建模
    已知函数方程创建曲线、曲面或几何体等时,多采用自底向上的方法建模。首先需要创建离散点,再由这些离散点创建线(直线、曲线、样
条线等)、面(平面、曲面)及几何体,下面几例的命令流说明基本过程。
         !EX2.9C 已知函数方程时的建模
         !玫瑰线1-----------------------------------------------------------------------------------
         !极坐标方程为
         finish  $ /clear  $ /prep7
         a=20  $ csys,1                                      ! 定义参数,设置柱坐标系
         *do,i,0,360*3                                         ! 循环创建 3×360 个点,即每 1 度创建一个关键点
         fei=i*acos(-1)/180                                 ! 计算 Φ 值(采用弧度)
         r0=a*sin(fei*4/3)                                   ! 计算该点的 ρ 值
         k,,r0,i  $ *enddo                                   ! 创建关键点
         *do,i,1,360*3  $ l,i,i+1  $ *enddo          ! 循环创建线

                ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体) - htbbzzg - htbbzzg的博客

 

         !  长辐圆内旋轮线--------------------------------------------------------
         !  参数方程
         !  x = (a - b) cos t + λ cos((a - b) t / b)
         !  y = (a - b) sin t - λ sin(a - b) t / b)

         finish  $ /clear  $ /prep7
         a=50  $ b=5  $ lmda=15  $ *afun,deg          ! 定义参数,设置角度单位为度
         *do,i,0,360                                                   ! 利用循环从 0°~360°
         x1=(a-b)*cos(i)+lmda*cos((a-b)/b*i)             ! 求得 X 坐标
         y1=(a-b)*sin(i)-lmda*sin((a-b)/b*i)                ! 求得 Y 坐标
         k,,x1,y1  $ *enddo                                        ! 定义关键点
         *do,i,1,360  $ l,i,i+1  $ *enddo                      ! 创建线

                              ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体) - htbbzzg - htbbzzg的博客

 

4.   旋转曲面或旋转体
    此类建模较为简单,如关键点旋转创建线、线旋转创建面、面旋转创建体等,但均需要预先设置旋转轴,在旋转时可设置旋转角度及分段。在土木工程中这种旋转结构较少,但在机械工程中有很多旋转结构,掌握旋转建模大有裨益。
         !  EX2.9D  旋转图素建模
         !类花瓶建模-----------------------------------------------------------------
         finish  $ /clear  $ /prep7
         K,1  $ K,2,100  $ K,3,300,400  $ K,4,150,550  $ k,5,130,880
         !  定义系列关键点
         K,6,300,1150  $ k,7,400,1100  $ k,8,500,1150                  ! 定义系列关键点
         bsplin,all                                                                             ! 利用关键点创建样条曲线
         k,1001,,1000  $ arotat,all,,,,,,1,1001,360,5
         !  创建旋转轴,并旋转线创建旋转面 

                              ANSYS 入门教程 (21) - 几何建模实例 (d 型钢、桥墩、异体) - htbbzzg - htbbzzg的博客
  评论这张
 
阅读(7992)| 评论(2)
推荐 转载

历史上的今天

在LOFTER的更多文章

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2016