注册 登录  
 加关注
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

htbbzzg的博客

与朋友们分享 CAE 资料和经验

 
 
 

日志

 
 

ANSYS 入门教程 (19) - 几何建模实例 (b 花键)  

2010-08-11 07:00:32|  分类: ANSYS 入门基础 |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

2.6.3   花键

    花键按齿形分为矩形花键和渐开线花键两种,按形式又分为内花键和外花键。矩形花键的齿廓为矩形;渐开线花键的齿廓为渐开线,按分度圆压力角的不同又分为 30° 压力角渐开线花键和 45° 压力角渐开线花键(也称三角形花键)两种。
    其建模基本方法为先创建键齿,再利用复制命令复制各个键齿,生成花键断面;拖拉或偏移面创建花键体。下面仅以矩形花键为例说明花键的建模过程和方法,矩形花键基本几何尺寸和键槽截面尺寸如图所示,命令流中没有考虑键槽部分。
    下面给出矩形外花键自顶向下建模方法,也可采用自底向上方法。

                ANSYS 入门教程 (9) - 几何建模实例 (b 花键和) - htbbzzg - htbbzzg的博客
 
    示例:
        ! EX2.3 矩形花键建模命令流
        finish  $ /clear  $ /prep7
        ! 定义花键参数------------------------------------------------------------------------------
        nd=10  $ wd=12  $ b=4  $ n=6  $ l0=20         ! 花键小径、大径、齿宽、齿数和花键长度
        ref=360/n  $ *afun,deg                                   ! 定义每齿范围所对应的α角度,并设角度单位为度
        allb=nd*sin(ref/2)                                           ! 求得在小径、大径和齿数一定时所允许的齿宽
        *if,b,gt,allb,then                                              ! 如果齿宽不合理则采用允许齿宽的一半
        b=nint(allb/2)  $ *endif
        cyl4,,,nd/2,,,ref/2                                            ! 创建半径为 Nd/2 圆心角为 REF/2 的圆面
        cyl4,,,wd/2,,,ref/2                                            ! 创建半径为 Wd/2 圆心角为 REF/2 的圆面
        aptn,all                                                           ! 分割上述两个面(布尔运算)
        wpoff,,b/2  $ wprota,,90                                  ! 移动工作平面 Y=B/2 并旋转
        asbw,3  $ adele,4,,,1                                      ! 切分面 A3,并删除面 A4
        arsymm,y,all  $ aadd,all                                  ! 以 Y 轴对称生成上述面,并相加形成一齿面
        wpcsys  $ csys,1                                             ! 工作平面归位,且设置柱坐标系 
                ANSYS 入门教程 (9) - 几何建模实例 (b 花键和) - htbbzzg - htbbzzg的博客
 
        lsel,s,loc,x,wd/2$ lcomb,all             ! 选择最外圆弧线,并合并它们
        allsel  $ agen,n,all,,,,ref                 ! 选择所有图素,然后复制
        aadd,all                                         ! 将全部面相加,得到矩形花键断面
                ANSYS 入门教程 (9) - 几何建模实例 (b 花键和) - htbbzzg - htbbzzg的博客
 
        *do,i,1,n                                    ! 以下采用 DO 循环合并内侧的圆弧线
        lsel,s,loc,x,nd/2                         ! 选择半径为 ND/2 的所有线
        lsel,r,loc,y,(i-1)*ref,i*ref             ! 再从中以角度进行选择
        lcomb,all$*enddo                      ! 合并所选择的线(可使所创建的体简洁)
        allsel$numcmp,all                     ! 选择所有图素,并压缩编号
        *get,kpmax,kp,0,num,max         ! 得到当前最大关键点号
        k,kpmax+1  $ k,kpmax+2,,,l0     ! 创建两个关键点
        l,kpmax+1,kpmax+2                   ! 创建直线,为拖拉面的路径
        *get,l1,line,0,num,max               ! 得到当前最大线号,即刚刚创建的线号
        vdrag,all,,,,,,l1                           ! 沿 L1 拖拉所有面创建花键体
        ldele,l1,,,1                                 ! 删除拖拉路径及其关键点
                ANSYS 入门教程 (9) - 几何建模实例 (b 花键和) - htbbzzg - htbbzzg的博客
 
 
2.6.4   带轮
    带轮分为平带轮和 V 带轮,平带轮建模较为简单,这里主要介绍 V 带轮的建模。V 带轮按结构分为实心式、腹板式、孔板式和轮幅式等,其基本建模方法均可先创建带轮断面,再绕轴旋转创建带轮体。对于孔板式和轮幅式则对模型再进一步处理即可。孔板式 V 带轮结构如图所示。
                ANSYS 入门教程 (9) - 几何建模实例 (b 花键和) - htbbzzg - htbbzzg的博客
 

         ! EX2.4 V 带轮建模命令流(未含键槽)
        finish  $ /clear  $ /prep7
        ! 1. 定义几何参数------------------------------------------------------------
        dd=200  $ fai=38  $ b=13  $ z=4                 ! 带轮基准圆直径、V 带楔角、沟槽顶宽、轮槽数
        s=14  $ ha=3                                               ! 孔板厚度 (可查表得到) 、基准圆到沟槽顶高度
        hf=9  $ e=15  $ f=10                                   ! 基准圆到沟槽底高度、沟槽间距、沟槽中心到边缘距离
        ks=8  $ r1=0.5  $ r2=1.0                             ! 孔数、齿顶倒角半径、齿根倒角半径
        r3=1.5  $ dta=6                                           ! 孔板与沟槽部或与轴部的倒角半径、轮缘厚度(可查表)
        c1=2  $c2=2                                                ! 轮槽外侧倒斜角尺寸(45 度)、轴倒斜角尺寸(45 度)
        pd=25  $ d0=24                                          ! 轮槽部底缘面的倾斜比例 (1:25)、轴直径
        d1=1.9*d0                                                   ! 一般采用 (1.8~2.0) d0
        S1=1.5*S                                                    ! 一般 S1 ≥ 1.5S
        s2=0.5*s                                                     ! 一般 S2 ≥ 0.5S
        l=2*d0                                                         ! 轴长度一般采用 (1.5~2.0) d0
        da=dd+2*ha                                               ! 带轮外径
        ub=(z-1)*e+2*f                                            ! 带轮宽
        rk1=dd/2-hf-dta-0.5*(ub-s)/pd-s2
        rk2=d1/2+0.5*(l-s)/pd+s1
        rk=(rk1-rk2)/2                                            ! 圆孔半径
        dk=rk1+rk2                                                ! 孔分布直径

        !2.创建轮槽部分截面----------------------------------------------------------------------
        *afun,deg  $ y0=hf+ha                               ! 设定角度单位为度、求沟槽全深
        b0=b-2*tan(fai/2)*y0                                  ! 求沟槽底宽
        local,12,0,-ub/2,dd/2-hf                             ! 设置 12 号局部坐标系
        k,,0,y0$k,,f-b/2,y0$k,,f-b0/2                       ! 最左侧 3 个关键点
        *do,i,1,z-1                                                   ! 中间部分关键点
            x0=f+(i-1)*e  $ k,,x0+b0/2
            k,,x0+b/2,y0  $ k,,x0+e-b/2,y0
            k,,x0+e-b0/2

        *enddo


        k,,ub-f+b0/2$k,,ub-f+b/2,y0                   ! 最右侧 3 个关键点
        k,,ub,y0
        *get,kp1,kp,0,num,max                           ! 得到当前最大关键点号,循环创建线
        *do,i,1,kp1-1  $ l,i,i+1  $ *enddo
        *get,l1,line,0,num,max                            ! 得到当前最大线号,对上述线进行倒角
        *do,i,1,z  $ j=4*(i-1) 

            lfillt,j+1,j+2,r1  $ lfillt,j+2,j+3,r2
            lfillt,j+3,j+4,r2  $ lfillt,j+4,j+5,r1

        *enddo
        csdele,12$ksll,s                                      ! 删除 12 号局部坐标系、选择与线相关的关键点
        ksel,inve  $ kdele,all                               ! 选择与线无关的关键点并删除
        allsel                                                       ! 选择所有图素
        numcmp,all                                             ! 压缩编号
        cm,l1cm,line                                            ! 将当前线定义元件 L1CM

        csdele,12$ksll,s                                      ! 删除 12号 局部坐标系、选择与线相关的关键点
        ksel,inve$kdele,all                                  ! 选择与线无关的关键点并删除
        allsel !选择所有图素
        numcmp,all                                             ! 压缩编号
        cm,l1cm,line                                            ! 将当前线定义元件 L1CM

                ANSYS 入门教程 (9) - 几何建模实例 (b 花键和) - htbbzzg - htbbzzg的博客
 
        !  3. 创建带轮腹板及轴部----------------------------------------------------------------------
        !  3.1 创建关键点和线
        *get,kp1,kp,0,num,max
        y0=dd/2-hf-dta  $ k,,-ub/2,y0+c1-c1/pd  $ k,,-ub/2+c1,y0-c1/pd
        k,,-s/2,y0-0.5*(ub-s)/pd  $ k,,-s/2,d1/2+0.5*(l-s)/pd
        k,,-l/2,d1/2  $ k,,-l/2,d0/2+c2  $ k,,-l/2+c2,d0/2  $ l,1,kp1+1
        *do,i,kp1+1,kp1+6  $ l,i,i+1  $ *enddo
        !  3.2  对腹板与轴部或轮槽部分倒角
        lsel,s,loc,y,y0-c1/pd,d1/2+0.5*(l-s)/pd  $ *get,l1,line,0,num,min
        l2=lsnext(l1)$lfillt,l1,l2,r3  $ lsel,all  $ lfillt,l2,l2+1,r3
        cmsel,u,l1cm
        !  3.3 对称生成另侧腹板及轴截面
        lsymm,x,all  $ ksel,s,loc,y,d0/2  $ *get,kp1,kp,0,num,min
        kp2=kpnext(kp1)  $ l,kp1,kp2  $ allsel
        nummrg,all  $ numcmp,all
                ANSYS 入门教程 (19) - 几何建模实例 (b 花键) - htbbzzg - htbbzzg的博客
 
        ! 4.  创建带轮截面并旋转创建体------------------------------------------
        al,all                                                   ! 由所有线创建面
        *get,kp1,kp,0,num,max                       ! 得到当前最大关键点号,创建两个关键点
        k,kp1+10,-uB/2  $ k,kp1+20,ub/2
        vrotat,all,,,,,,kp1+10,kp1+20,,ks         ! 旋转面创建体(KS 个体)
        kdele,kp1+10,kp1+20,10                    ! 删除上述两个关键点
                ANSYS 入门教程 (19) - 几何建模实例 (b 花键) - htbbzzg - htbbzzg的博客
 
        !  5.  创建腹板上的圆孔------------------------------------------------------------------------
        cm,v1cm,volu                         ! 定义上述体为元件 V1CM
        wpoff,ub/2  $ wprota,,,90        ! 移动工作平面并旋转
        x0=dk/2*sin(180/ks)               ! 圆孔中心 X 坐标
        y0=dk/2*cos(180/ks)              ! 圆孔中心 Y 坐标
        cyl4,x0,y0,rk,,,,-ub                 ! 创建圆柱体,拟与带轮体相减
        *get,v1,volu,,num,max            ! 得到圆柱体编号
        cswpla,12,1                            ! 在当前工作平面原点定义 12 号局部柱坐标系
        vgen,ks,v1,,,,360/ks               ! 复制 V1 圆柱体
        cmsel,u,v1cm                         ! 不选择元件 V1CM
        cm,v2cm,volu                         ! 定义这些柱体为元件 V2CM
        allsel
        vsbv,v1cm,v2cm                     ! V1CM 减 V2CM,形成板孔式带轮
        !  6.  整理和视图---------------------------------------------------------------------------------
        csdele,12  $ wpcsys  $ numcmp,all
        /view,1,1,1,1  $ /ang,1,-90,ys,1  $ vplot
                ANSYS 入门教程 (19) - 几何建模实例 (b 花键) - htbbzzg - htbbzzg的博客
 
下接:2.6.5 齿轮
  评论这张
 
阅读(2252)| 评论(0)
推荐 转载

历史上的今天

在LOFTER的更多文章

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2016