注册 登录  
 加关注
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

htbbzzg的博客

与朋友们分享 CAE 资料和经验

 
 
 

日志

 
 

ANSYS 入门教程 (20) - 几何建模实例 (c 齿轮)  

2010-08-12 06:38:10|  分类: ANSYS 入门基础 |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

2.6.5  齿轮

    齿轮按齿向分为直齿轮、斜齿轮和人字齿轮,按齿廓分为渐开线齿轮、摆线齿轮和圆弧齿轮,另外尚分圆柱齿轮和圆锥齿轮。常用齿轮主要有盘式齿轮、腹板式齿轮和轮幅式齿轮,并且都有圆柱齿轮和锥齿轮两种。齿轮形式较多,其建模方式也不相同,并且在建模过程中尚要考虑将来的网格划分,因此齿轮建模要复杂一些。
    腹板式渐开线直齿标准外齿轮结构如图所示,其计算公式在命令流中给出,详细可参考有关资料。

                ANSYS 入门教程 (20) - 几何建模实例 (c 齿轮) - htbbzzg - htbbzzg的博客
  
    渐开线是基圆的渐开线,因此齿廓线是整个渐开线的一部分,即从齿根到齿顶为一段渐开线。又因基圆直径可能大于齿根圆直径,此时基圆以内到齿根部分的齿廓线采用渐开线始点的切线,即相切于渐开线始点(在基圆上)的向心线,也可采用平行于半齿中线的直线,以避免发生根切现象。
    示例:
        !  EX2.5  腹板式渐开线直齿圆柱齿轮建模
        finish  $ /clear  $ /prep7
        !  1. 定义齿轮参数-------------------------------------------------------------------------
        m=5  $ z=55  $ refa=20            ! 齿轮模数、齿轮齿数、齿形角(即分度圆上的压力角)
        hax=1  $ cx=0.25                      ! 齿顶高系数、顶隙系数
        rouf=0.38*m  $ ks=6                 ! 齿根圆角半径、腹板上的圆孔数
        !  1.1 以下多为计算值,也可调正,但注意相互关系-------------------------
        ha=hax*m  $ hf=(hax+cx)*m      ! 齿顶高、齿根高
        pi=acos(-1)                               ! 参数 π
        d=m*z                                       ! 分度圆直径
        db=d*cos(refa*pi/180)              ! 基圆直径
        da=d+2*ha$df=d-2*hf               ! 齿顶圆直径、齿根圆直径
        alfad=acos(db/da)                    ! 齿顶圆压力角
        *if,db,gt,df,then                         ! 如果基圆直径大于齿顶圆直径则
        alfag=0.0$*else                        ! 令齿根圆压力角为 0,否则
        alfag=acos(db/df)  $ *endif       ! 齿根求得圆压力角
        b=0.22*D                                  ! 齿宽,可根据齿的软硬及与轴承相对位置选择系数
        !  1.2  轴孔参数设定----------------------------
        dta=6*m                                    ! 轮齿部厚度,一般为 (5~6) m
        dax=d/5                                     ! 轴孔直径,可据自行设定,这里为 1/5 分度圆直径
        d2=1.6*dax                                ! 轴孔壁外缘直径
        d1=0.25*(da-2*dta-d2)               ! 腹板上圆孔直径
        d0=0.5*(da-2*dta+d2)                ! 腹板上圆孔中心的分布圆直径
        c=0.3*b                                      ! 腹板厚度,一般为 0.3B
        nj=0.5*m$nj1=0.5*m                   ! 外部倒角和轴孔内部倒角
        r=5                                             ! 腹板倒角半径
        s=1.5*dax                                   ! 轴孔长度,一般采用 (1.2~1.5) dax 且 ≧ b
        !  2. 创建齿廓面-------------------------------------------------------------------------------
        !  2.1  用极坐标方程计算渐开线上的点,取 20 个点拟合该渐开线
        !方程为:ρ=a/cosα,θ=tanα-α,其中 a 为基圆半径,α 为压力角,θ 为极角
        csys,1  $ n=20                                         ! 设置柱坐标系,并设 20 个点
        *do,i,1,n                                                   ! 利用 DO 循环创建关键点
        alfai=alfag+((alfad-alfag)/(n-1))*(i-1)        ! 求得 I 点的 α
        roui=0.5*db/cos(alfai)                               ! 求得 I 点的 ρ
        ctai=tan(alfai)-alfai                                    ! 求得 I 点的 θ
        k,i,roui,ctai*180/pi$*enddo                        ! 在柱坐标系中创建关键点
                ANSYS 入门教程 (20) - 几何建模实例 (c 齿轮) - htbbzzg - htbbzzg的博客
 
        !  2.2  利用上述关键点创建线,并合并之----------------------------
        *do,i,1,n-1  $ l,i,i+1  $ *enddo                         ! 利用 DO 循环创建线
        ctai=(tan(refa*pi/180)-refa*pi/180)*180/pi       ! 求得齿形角的 θ
        ctai=ctai+360/(4*z)                                          ! 求得上述渐开线的旋转角
        lgen,,ALL,,,,-ctai,,,,1                                        ! 旋转该渐开线
        csys,0                                                              ! 设置直角坐标系创建关键点,并准备对称生成线
        *if,db,gt,df,then                                                ! 如果基圆直径大于齿顶圆直径则在齿根圆上创建
        k,n+1,kx(1)-(db-df)/2,ky(1)                               ! 创建关键点,采用渐开线始点的切线
        l,1,n+1  $ *endif                                               ! 并与原关键点 1 连线
        lcomb,all  $ numcmp,all                                    ! 合并所有线,并压缩图素编号
                ANSYS 入门教程 (20) - 几何建模实例 (c 齿轮) - htbbzzg - htbbzzg的博客
 
        !  2.3 做对称操作----------------------------
        lsymm,y,all                 !设置直角坐标系,并关于Y轴对称操作
        !  2.4 在齿根圆上创建单齿部分的两个关键点,并倒角----------------------------
        csys,1                                         ! 设置柱坐标系
        k,5,0.5*df,360/(2*z)                     ! 创建关键点 5
        k,6,0.5*df,-360/(2*z)                    ! 创建关键点 6
        kp1=knear(6)  $ l,6,kp1               ! 得到距离关键点 6 最近的点,并创建线
        kp1=knear(5)  $ l,5,kp1               ! 得到距离关键点 5 最近的点,并创建线
        lfillt,1,3,rouf  $ lfillt,2,4,rouf          ! 对线实施倒角操作
        ksel,s,loc,x,da/2                           ! 选择齿顶的两个关键点
        *get,kp1,kp,0,num,min                 ! 得到选择集中的最小关键点号
        kp2=kpnext(kp1)  $ l,kp1,kp2       ! 得到另外一个关键点号,并创建线
        allsel
        numcmp,all
                ANSYS 入门教程 (20) - 几何建模实例 (c 齿轮) - htbbzzg - htbbzzg的博客
 
        !  2.5  复制单齿齿廓线 Z 个,利用线创建面;建议一另外圆面相减,形成齿廓面
        lgen,z,all,,,,360/z                          ! 复制单齿廓线Z次,形成整个齿廓线
        nummrg,kP  $ al,all                      ! 合并关键点,创建齿廓面
        cyl4,,,da/2-0.5*(dta+ha+hf)          ! 创建圆面,其大小在齿根和腹板齿缘之间
        asba,1,2  $ numcmp,all                ! 齿廓面减上述圆面,形成中空的齿廓面
        csys,0  $ agen,1,1,,,,,b/2,,,1         ! 设置直角坐标系,移动该面到 B/2 位置
        !  上述操作目的是由面拖拉形成体后即为齿部,但由于与腹板部分创建方法(旋转)不同,
        !  因此需要找寻一个结合面,这里取 δ-h 的 1/2 处。
                ANSYS 入门教程 (20) - 几何建模实例 (c 齿轮) - htbbzzg - htbbzzg的博客
 
                ANSYS 入门教程 (20) - 几何建模实例 (c 齿轮) - htbbzzg - htbbzzg的博客
 
        !3.创建腹板及轴孔的截面-------------------------------------------------------------------
        !3.1 创建腹板及轴孔截面的一半线----------------------------
        *get,kp0,kp,0,num,max                         ! 得到当前最大关键点号,并创建关键点
        k,kp0+1,0,dax/2  $ k,kp0+2,0,dax/2,s/2-nj1  $ k,kp0+3,0,dax/2+nj1,s/2
        k,kp0+4,0,d2/2-nj,s/2  $ k,kp0+5,0,d2/2,s/2-nj  $ k,kp0+6,0,d2/2,c/2
        k,kp0+7,0,da/2-dta,c/2  $ k,kp0+8,0,da/2-dta,b/2-nj  $ k,kp0+9,0,da/2-dta+nj,b/2
        k,kp0+10,0,da/2-0.5*(dta+ha+hf),b/2  $ k,kp0+11,0,da/2-0.5*(dta+ha+hf)
        *do,i,1,10  $ l,kp0+i,kp0+i+1$*enddo                 ! 创建线
 
                ANSYS 入门教程 (20) - 几何建模实例 (c 齿轮) - htbbzzg - htbbzzg的博客
 
         !  3.2  对上述线进行倒角----------------------------
        lsel,s,loc,x,0                                         ! 选择 X=0 的线
        lsel,r,loc,y,d2/2,da/2-dta-0.01              ! 从中选择 Y 在 d2/2 和 da/2-dta-0.01 之间的线
        *get,l1,line,0,num,min                          ! 得到当前选择集中最小线号
        l2=lsnext(l1)                                         ! 得到另外一条线的线号
        lfillt,l1,l2,r                                             ! 倒角操作
        lsel,s,loc,x,0  $ lsel,r,loc,y,d0/2-d1/2,da/2-dta
        *get,l1,line,0,num,min
        l2=lsnext(l1)  $ lfillt,l1,l2,r                     ! 同上倒角操作过程
        !  3.3  创建腹板及轴孔截面----------------------------
        lsel,s,loc,x,0                                        ! 选择腹板及轴孔截面的线
        lsel,r,loc,y,dax/2,da/2-0.5*(dta+ha+hf)
        lsymm,z,all                                          ! 关于 Z 轴对称生成线
        nummrg,kp  $ numcmp,all                   ! 合并关键点并压缩编号
        al,all                                                    ! 创建腹板及轴孔截面
                ANSYS 入门教程 (20) - 几何建模实例 (c 齿轮) - htbbzzg - htbbzzg的博客
 
         !  3.4  旋转面创建体----------------------------
        *get,kp0,kp,0,num,max                         ! 得到当前最大关键点号
        k,kp0+100,,,b/2  $ k,kp0+101,,,-b/2      ! 创建两个关键点,用于旋转轴
        vrotat,2,,,,,,kp0+100,kp0+101,,ks         ! 旋转腹板及轴孔截面创建体
        !  3.5  拖拉齿廓面创建体----------------------------
        l,kp0+100,kp0+101                               ! 连接旋转轴的两个关键点
        *get,l1,line,0,num,max                           ! 得到该线的编号
        vdrag,1,,,,,,l1                                         ! 沿该线拖拉创建齿部体
        allsel                                                     ! 选择所有图素
        nummrg,all  $ numcmp,all                     ! 合并所有图素,并压缩编号
                ANSYS 入门教程 (20) - 几何建模实例 (c 齿轮) - htbbzzg - htbbzzg的博客
 
        !  4.  创建圆孔,方法同 V 带轮---------------------------------------------------------------
        CM,V1CM,VOLU                        ! 定义上述体为元件 V1CM
        *afun,deg  $ WPOFF,,,-b           ! 设置角度单位,移动工作平面
        X0=D0/2*SIN(180/KS)                 ! 圆孔中心 X 坐标
        Y0=D0/2*COS(180/KS)              ! 圆孔中心 Y 坐标
        CYL4,X0,Y0,d1/2,,,,2*b              ! 创建圆柱体,拟与齿轮体相减
        *GET,V1,VOLU,,NUM,MAX         ! 得到圆柱体编号
        wpcsys
        csys,1                                        ! 设置柱坐标系
        VGEN,KS,V1,,,,360/KS              ! 复制 V1 圆柱体 KS 个
        CMSEL,U,V1CM                        ! 不选择元件 V1CM
        CM,V2CM,VOLU                       ! 定义这些柱体为元件 V2CM
        ALLSEL
        VSBV,V1CM,V2CM                   ! V1CM 减 V2CM,形成板孔式带轮
        !  5. 整理和视图-------------------------------------------------------------------------
        /VIEW,1,1,1,1
       vplot
                                                                                        
                ANSYS 入门教程 (20) - 几何建模实例 (c 齿轮) - htbbzzg - htbbzzg的博客
                 ANSYS 入门教程 (20) - 几何建模实例 (c 齿轮) - htbbzzg - htbbzzg的博客
  评论这张
 
阅读(2575)| 评论(12)
推荐 转载

历史上的今天

在LOFTER的更多文章

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2016